將MS-Access string> 255個字符傳遞到MS-Word字段

Question

我使用.FormFields("WordBookmarkName").Result = stringFromAccess方法將數據從MS-Access傳遞到MS-Word文檔。

看來它只能傳遞255個字符。有什麼方法可以在MS-Word中傳遞給我的領域？

編輯：

這是代碼的簡化版本，我使用的作品確定爲255個字符：

Dim startForms As String 
Dim appWord As Word.Application 
Dim doc As Word.Document 

startForms = String(256, "x") 

Set appWord = GetObject(, "Word.Application") 'Set appWord object variable to running instance of Word. 

If Err.Number <> 0 Then 

    Set appWord = New Word.Application 'If Word isn't open, create a new instance of Word. 

End If 

Set doc = appWord.Documents.Open("C:\myFolder\MyForm.docx", , True) 

With doc 

    .FormFields("wdStartForms").Result = "" 'Clear anything currently in the form's field 
    .FormFields("wdStartForms").Result = startForms 

    .Visible = True 
    .Activate 

End With 

Set doc = Nothing 
Set appWord = Nothing 

JohnnyBones：這是我經過改編的代碼你的答案;使用ActiveDocument是行不通的，所以我繼續使用doc參考我就做，它似乎後，與256+字符來確定：

Dim startForms As String 
Dim appWord As Word.Application 
Dim doc As Word.Document 

startForms = String(256, "x") 

Set appWord = GetObject(, "Word.Application") 'Set appWord object variable to running instance of Word. 

If Err.Number <> 0 Then 

    Set appWord = New Word.Application 'If Word isn't open, create a new instance of Word. 

End If 

Set doc = appWord.Documents.Open("C:\myFolder\MyForm.docx", , True) 

With doc 

    .FormFields("wdStartForms").Result = "" 'Clear anything currently in the form's field 
    .Bookmarks("wdStartForms").Range.Fields(1).Result.Text = startForms 
    .Visible = True 
    .Activate 

End With 

Set doc = Nothing 
Set appWord = Nothing 

Answer 1

如果你使用：

Dim FmFld As FormField, Str1 As String 
Str1 = (a long string > 256 characters) 

Set FmFld = ActiveDocument.FormFields(1) 
FmFld.Result = Str1 

你會得到一個錯誤：「字符串太長」（一個荒謬的「設計」功能，因爲你可以手動完成而沒有問題！）。

相同的，如果你使用：

ActiveDocument.Formfields("Text1").Result = Str1 

你可以避開這個問題，通過使用：

ActiveDocument.Unprotect 
FmFld.Range.Fields(1).Result.Text = Str1 
ActiveDocument.Protect Type:=wdAllowOnlyFormFields, NoReset:=True 

或者如果你指的是按名稱formfield：

ActiveDocument.Unprotect 
ActiveDocument.Bookmarks("Text1").Range.Fields(1).Result.Text = Str1 
ActiveDocument.Protect Type:=wdAllowOnlyFormFields, NoReset:=True 

您也可以嘗試傳遞多個字符串並將它們連接起來，將每個字符串切分成少於255個字符的塊。