等效代碼2005

Question

我在VB .NET下面的代碼示例2008

Public Function CheckPathFunction(ByVal path As String) As Boolean 
    Return System.IO.File.Exists(path) 
End Function 

Public Function PathExists(ByVal path As String, ByVal timeout As Integer) As Boolean 
    Dim exists As Boolean = True 
    Dim t As New Thread(DirectCast(Function() CheckPathFunction(path), ThreadStart)) 

    t.Start() 

    Dim completed As Boolean = t.Join(timeout) 
    If Not completed Then 
     exists = False 
     t.Abort() 
    End If 

    Return exists 
End Function 

不幸的是我用VB .NET 2005和.NET框架2.0的工作;我如何才能完成相同的VB .net 2005 ?, VB .net 2005不支持對應於代碼行num的語法。 3：

Function() CheckPathFunction(path) 

請注意，調用該函數需要一個參數和返回值

---

我使用委託作爲下一表示試過，但不起作用

Private Delegate Function CheckPath(ByVal path As String) As Boolean 

Public Function CheckPathFunction(ByVal path As String) As Boolean 
    Return IO.File.Exists(path) 
End Function 

Public Function PathExists(ByVal path As String, ByVal timeout As Integer) As Boolean 
    Dim checkPathDelegate As New CheckPath(AddressOf CheckPathFunction) 

    Dim exists As Boolean = True 
    Dim t As New Thread(checkPathDelegate(path)) 

    t.Start() 

    Dim completed As Boolean = t.Join(timeout) 
    If Not completed Then 
     exists = False 
     t.Abort() 
    End If 

    Return exists 
End Function 

謝謝

Answer 1

通過@eol以作爲基部結構的代碼最終的工作代碼是：

Class KeyValuePair 
     Public Path As String 
     Public Found As Boolean 
End Class 

Public Sub CheckPathFunction(ByVal dataObject As Object) 
     dataObject.Found = IO.Directory.Exists(dataObject.Path) 
End Sub 

Public Function PathExists(ByVal path As String, ByVal timeout As Integer) As Boolean 
     Dim exists As Boolean 

     Dim data As New KeyValuePair 
     data.Path = path 

     Dim t As New Thread(New ParameterizedThreadStart(AddressOf CheckPathFunction)) 
     t.Start(data) 

     Dim completed As Boolean = t.Join(timeout) 
     If Not completed Then 
      exists = False 
      t.Abort() 
     Else 
      exists = data.Found 
     End If 

     Return exists 
End Function 

Answer 2

請參閱this MSDN article使用ParameterizedThreadSta調用Thread構造函數rt代表。既然你在VB是你應該能夠只是做到這一點：

Dim t As New Thread(AddressOf CheckPathFunction) 

t.Start(path) 

好，這是對發射了線程的答案。但是我同意SteveDog的觀點，即只有在線程完成或超時的情況下，它纔會實際返回文件是否存在。

編輯返回值： 獲取該值的一種方法是傳遞一個對象，而不僅僅是路徑。然後使用該對象傳回結果。

所以聲明一個類，如：

Class DataHolder 
    Public Path As String 
    Public Found As Boolean 
End Class 

變化CheckPathFunction像：

Public Sub CheckPathFunction(ByVal rawData As Object) 
    Dim data As DataHolder = DirectCast(rawData, DataHolder) 
    data.Found = System.IO.File.Exists(data.Path) 
End Sub 

和更改等PathExists：

Public Function PathExists(ByVal path As String, ByVal timeout As Integer) As Boolean 
    Dim exists As Boolean 
    Dim t As New Thread(AddressOf CheckPathFunction) ' (DirectCast(Function() CheckPathFunction(path), ThreadStart)) 
    Dim data As DataHolder = New DataHolder 
    data.Path = path 
    t.Start(data) 

    Dim completed As Boolean = t.Join(timeout) 
    If Not completed Then 
     exists = False 
     t.Abort() 
    Else 
     exists = data.Found 
    End If 

    Return exists 
End Function