如何對Dlang中的對象數組進行排序？

Question

如何對D中的用戶定義對象數組進行排序？

從C++背景的，我想你要申報運算符重載存儲陣列中的類型，或者使用比較器功能...

如何做到這將是一個例子非常感激。

Answer 1

你會想要std.algorithm.sort默認情況下使用< b，所以你的班級可以覆蓋opCmp利用這一點。

更新：只是替代glampert的例子。

import std.algorithm; 
import std.stdio; 

class Test { 

    int x; 

    this(int x) 
    { 
     this.x = x; 
    } 
} 

void main() 
{ 
    Test[] array = [new Test(3), new Test(1), new Test(4), new Test(2)]; 

    writeln("Before sorting: "); 
    writeln(array.map!(x=>x.x)); 

    sort!((a,b)=>a.x < b.x)(array); // Sort from least to greatest 

    writeln("After sorting: "); 
    writeln(array.map!(x=>x.x)); 
} 

Answer 2

使用std.algorithm.sort和opCmp超載：

import std.algorithm; 
import std.stdio; 

class Test 
{ 
    int x; 

    this(int x) 
    { 
     this.x = x; 
    } 

    int opCmp(ref const Test other) const 
    { 
     if (this.x > other.x) 
     { 
      return +1; 
     } 
     if (this.x < other.x) 
     { 
      return -1; 
     } 
     return 0; // Equal 
    } 
}; 

void main() 
{ 
    Test[] array = [new Test(3), new Test(1), new Test(4), new Test(2)]; 

    writeln("Before sorting: "); 
    for (int i = 0; i < array.length; ++i) 
    { 
     write(array[i].x); 
    } 
    writeln(); 

    sort(array); // Sort from least to greatest using opCmp 

    writeln("After sorting: "); 
    for (int i = 0; i < array.length; ++i) 
    { 
     write(array[i].x); 
    } 
    writeln(); 
} 

這將輸出：

Before sorting: 
3142 
After sorting: 
1234