if getelementby class

Question

首先，我對編程比較陌生。我一直主要熟悉VBA。我之前在這裏提過問題，到目前爲止，答覆非常有幫助，所以我再次嘗試我的運氣。

我要去這個網站：http://www.otcmarkets.com/stock-screener

我想我的腳本是這樣說的：

if ElementClassName("listingOdd").innertext = "USA, NV" 
then GetElementsbyClassName("listingOddlistingOdd whiteSpaceNormal").innertext 

我也想它遍歷並單擊下一步按鈕，這是這個網站的背後直到它完成： a href =「javascript：void（null）;」>下一個& gt;/a

歡迎任何幫助，我一直在搜索過去的問題和看教程，不要問我是否在這個問題上沒有認真地敲我的頭。非常感謝提前

這是一些代碼，我都試過了，並出現以下錯誤：「對象犯規支持此方法」 有從試驗和錯誤

Sub t() 


Dim IE As Object 
Set IE = CreateObject("InternetExplorer.Application") 
IE.Visible = False 

IE.navigate "http://www.otcmarkets.com/stock-screener" 

Do 
DoEvents 
Loop Until IE.readyState = READYSTATE_COMPLETE 
Dim Doc As HTMLDocument 
Set Doc = IE.document 
Dim sDD As String 
Dim lnk As Variant 
sDD = Trim(Doc.GetElementbyClassName("listingOddlistingOdd whiteSpaceNormal").innerText) 
'If lnk.classame.innerText = "USA, NV" Then 
If lnk.innerText = "USA, NV" Then 
'If ElementClassName("listingOdd")(0).innerText = "USA, NV" Then 
'sDD 
'sDD = Trim(Doc.GetElementbyClassName("listingOddlistingOdd whiteSpaceNormal").innerText) 
MsgBox sDD 
End If 




End Sub 

對不起註釋掉了很多意大利麪代碼，就像我說的我是新的

Answer 1

我並不十分清楚你想要得到什麼（爲什麼不只是使用方便的「下載全部」鏈接在頁面頂部？）

編輯 - 在工作表上放置單元格值 EDIT2 - 單擊「下一個」鏈接。 編輯3 - 環

雖然這種事情是一個總兔子洞。

Sub Tester() 
Dim doc As Object 
Dim IE As Object, nxt 
Dim rng As Range, x As Integer 

    Set rng = ThisWorkbook.Sheets("sheet1").Range("A2") 
    Set IE = CreateObject("InternetExplorer.Application") 
    IE.Visible = True 
    IE.navigate "http://www.otcmarkets.com/stock-screener" 
    WaitForLoad IE 

    Set nxt = GetNext(IE) 
    Do While Not nxt Is Nothing 
     ExtractTableContent IE, rng 
     nxt.Click 
     WaitForLoad IE 
     Set nxt = GetNext(IE) 
    Loop 
End Sub 

Sub WaitForLoad(IE As Object) 
    Do: DoEvents: Loop Until IE.readyState = 4 'READYSTATE_COMPLETE 
    Application.Wait Now + TimeSerial(0, 0, 3) 
End Sub 
'copy table content 
Sub ExtractTableContent(ByRef IE As Object, ByRef rng As Range) 
    Dim tableDiv As Object, r As Object, rw As Object, x As Long 

    Set tableDiv = IE.document.getelementbyid("stockScreenerResults") 
    Set r = tableDiv.getelementsbytagname("table")(0).Rows 
    For Each rw In r 
     For x = 1 To rw.Cells.Length 
      rng.Offset(0, x - 1).Value = rw.Cells(x - 1).innerText 
     Next x 
     Set rng = rng.Offset(1, 0) 
    Next rw 
End Sub 

'find the link which takes you to the next page... 
Function GetNext(IE As Object) As Object 
    Dim links, l As Object, rv As Object, cn As Object 
    Set links = IE.document.getelementsbytagname("a") 
    For Each l In links 
     If l.innerText Like "*next*" Then 
     Set rv = l 
     Exit For 
     End If 
    Next l 
    Set GetNext = rv 
End Function