按鈕的文本打印非常浪費。我怎樣才能利用浪費的空間？

Question

在我的Windows窗體上，我添加了一個名爲Button1的按鈕，其中包含標準文本Button1。

此按鈕有一些標準屬性的改變：

• 字體 = Arial字體，標準，9.75（選擇10）
• 的FlatStyle =扁平
• FlatAppearance.BorderSize = 0
• 大小 = 60; 60

看來，可用空間的使用非常浪費。

當然Button1的可能在一個單一的線路被打印，甚至可能Button111。 Padding屬性未被觸及，爲0; 0; 0; 0.

問題：是否可以使用更多可用空間（創建專用的用戶控件除外）？

Answer 1

由於用戶ChristopherKyleHorton，誰發現這個問題的possible duplicate（雖然標有一般的.Net關鍵字，引發大多數是C＃的答案），我由用戶yarecki沿下班。

我改進了一下，並對它進行了廣泛的評論。如果您還需要一個真正平坦的按鈕（沒有邊框，包括所有像素在內的文字使用情況），請將以下代碼放入新的類庫項目中，並在工具箱中包含對其的引用。

'In order to see the Text property in the appearance section of the properties 
'window, the Category attribute needs to be modified, which requires the 
'inclusion of the ComponentModel namespace. 
Imports System.ComponentModel 

Public Class FlatButton 
Inherits Button 

'============================================================================ 
'VARIABLES. 
'============================================================================ 

'Property variables. 
Private gsText As String 

'============================================================================ 
'PROPERTIES. 
'============================================================================ 

'Modifying the category attribute requires the import of the ComponentModel 
'namespace. 
<Category("Appearance")> 
Public Overrides Property Text() As String 
    Get 
     Return gsText 
    End Get 
    Set(ByVal sValue As String) 
     If sValue <> gsText Then 'If the new text differs from the old 
      gsText = sValue   'one indeed, store it. 
      Me.Invalidate()   'Invalidate causes a paint message to be 
     End If      'sent to the control. 
    End Set 
End Property 

'============================================================================ 
'EVENTS. 
'============================================================================ 

'When the flat button control is being *displayed* for the first time, the 
'HandleCreated event is fired. In it, the button's typical characteristics 
'are set. 
Private Sub FlatButton_HandleCreated(sender As Object, e As EventArgs) _ 
    Handles Me.HandleCreated 

    FlatStyle = FlatStyle.Flat  'Make the button flat. 
    FlatAppearance.BorderSize = 0 'Display no borders at all. 
End Sub 

'Fires when the Text property is modified, enforced by the Invalidate 
'method coded there. 
Protected Overrides Sub OnPaint(e As PaintEventArgs) 
    Dim sSaveText As String   'Saves the current text. 

    sSaveText = Me.Text    'Save the current text. 
    gsText = String.Empty   'Blank the Text property. 
    MyBase.OnPaint(e)    'Erase the client area. 
    gsText = sSaveText    'Restore the Text property. 

    '(Using has the effect to automatically dispose the used objects when 
    'done.) 

    'Acquire a new SolidBrush resource with the ForeColor color. 
    Using oBrush = New SolidBrush(ForeColor) 

     'Acquire a new StringFormat resource centering the text. 
     Using oStringFormat = New StringFormat() With 
      {.Alignment = StringAlignment.Center, 
      .LineAlignment = StringAlignment.Center} 

      'Draw the string contained in Text with the acquired brush in the 
      'acquired string format, in the button's client rectangle, which 
      'is enlarged by 3 pixels in each direction. The original client 
      'rectangle has a padding of 3 pixels to allow for a 2 pixels wide 
      'border (3D), and a 1-pixel margin between the border and the 
      'actual text. 
      e.Graphics.DrawString(Me.Text, Me.Font, oBrush, 
       Rectangle.Inflate(ClientRectangle, 3, 3), oStringFormat) 
     End Using     'Dispose the StringFormat object. 
    End Using      'Dispose the oBrush object 
End Sub 

End Class 

採用這種控制確實減少文本週圍填充，前（左）和（右）後的比較：

希望這可以幫助別人也是如此。