如何在xsl轉換過程中向組件添加條件？

Question

我正在嘗試在收穫目錄期間應用的xsl轉換期間在wix中添加組件條件。我試過這個模板，但它不工作。

<xsl:stylesheet version="1.0" 
       xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
       xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
       exclude-result-prefixes="msxsl" 
       xmlns:wix="http://schemas.microsoft.com/wix/2006/wi" 
       xmlns:netfx="http://schemas.microsoft.com/wix/NetFxExtension" 
       xmlns:util="http://schemas.microsoft.com/wix/UtilExtension"> 
    <xsl:output method="xml" indent="yes" /> 

    <xsl:strip-space elements="*" /> 


    <xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()" /> 
    </xsl:copy> 
    </xsl:template> 
    <xsl:template match="wix:Component"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
     <Condition Level="1"><![CDATA[MYPROP="1"]]></Condition> 
    </xsl:copy> 
    </xsl:template> 

雖然輸入heat.exe將目錄位置和XML生成將由熱與改造一起做我認爲，作爲輸入將中間XML

輸入

<?xml version="1.0" encoding="utf-8"?> 
<Wix xmlns="http://schemas.microsoft.com/wix/2006/wi"> 
    <Fragment> 
     <DirectoryRef Id="MyDir"> 
      <Component Id="CefSharp.BrowserSubprocess.Core.dll_x86" Guid="06CF68DB-C4D3-45D3-8619-982C7963ADC6"> 
       <File Id="CefSharp.BrowserSubprocess.Core.dll_x86" KeyPath="yes" Source="$(var.CefSharpDirx86)\CefSharp.BrowserSubprocess.Core.dll" /> 

      </Component> 

     </DirectoryRef> 
    </Fragment> 
</Wix> 

輸出

<?xml version="1.0" encoding="utf-8"?> 
<Wix xmlns="http://schemas.microsoft.com/wix/2006/wi"> 

     <Fragment> 
       <DirectoryRef Id="MyDir"> 
        <Component Id="CefSharp.BrowserSubprocess.Core.dll_x86" Guid="06CF68DB-C4D3-45D3-8619-982C7963ADC6"> 
         <File Id="CefSharp.BrowserSubprocess.Core.dll_x86" KeyPath="yes" Source="$(var.CefSharpDirx86)\CefSharp.BrowserSubprocess.Core.dll" /> 
         <Condition Level="1"><![CDATA[MYPROP="1"]]></Condition> 
        </Component> 

       </DirectoryRef> 
      </Fragment> 
    </Wix> 

我是新來的XSLT世界。請建議。

Answer 1

- 響應編輯，以澄清 -

不知道你的 「不工作」 的意思。當然，你必須將新的元素在同一個名稱空間作爲其母公司，以獲得預期的結果：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:wix="http://schemas.microsoft.com/wix/2006/wi"> 
<xsl:output method="xml" indent="yes" cdata-section-elements="wix:Condition"/> 
<xsl:strip-space elements="*" /> 

<xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()" /> 
    </xsl:copy> 
    </xsl:template> 

<xsl:template match="wix:Component"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
     <xsl:element name="Condition" namespace="http://schemas.microsoft.com/wix/2006/wi"> 
      <xsl:attribute name="level">1</xsl:attribute> 
      <xsl:text>MYPROP="1"</xsl:text> 
     </xsl:element> 
    </xsl:copy> 
</xsl:template> 

</xsl:stylesheet> 

看到它的工作：http://xsltransform.net/bFN1yai