爲什麼我的application.ontime不能在if語句中工作？ VBA

Question

我有一個application.ontime例程如下。

Sub timer() 

If Hour(Time) <= 15 Or Hour(Time) >= 22 Then 

    On Error Resume Next 

    Application.OnTime EarliestTime:=ThisWorkbook.Worksheets("Sheet1").Range("K5"), Procedure:="dataextract", Schedule:=False 

    On Error GoTo 0 

    ThisWorkbook.Worksheets("Sheet1").Range("K5") = Now + TimeSerial(0, WorksheetFunction.Floor(Minute(Now), 5) + 5 - Minute(Now), 1 - Second(Now)) 

    Application.OnTime EarliestTime:=ThisWorkbook.Worksheets("Sheet1").Range("K5"), Procedure:="dataextract", Schedule:=True 

End If 


End Sub 

我想這個程序至10點之間上day 0上day 1運行到下午4點，然後自行重新啓動晚上10點day 1到下午4點day 2，等等。代碼在下午4點停止，但不會在晚上10點重新啓動。正如你所看到的，我永遠不會轉身schedule:=false，所以我不明白爲什麼它不會重新啓動..？

Answer 1

我敢肯定，我在這裏犯了一個錯誤的地方，但你應該明白我的意思...

Sub timer() 

    Const PROC As String = "dataextract" 
    Const INTV_MIN As Long = 5 

    Dim rTime As Range 

    Set rTime = ThisWorkbook.Worksheets("Sheet1").Range("K5") 

    On Error Resume Next 
    Application.OnTime EarliestTime:=rTime.Value, Procedure:=PROC, Schedule:=False 
    On Error GoTo 0 

    If Hour(Time) <= 15 Or Hour(Time) >= 22 Then 
     '5min from now 
     rTime.Value = Now + TimeSerial(0, _ 
         WorksheetFunction.Floor(Minute(Now), INTV_MIN) + INTV_MIN - Minute(Now), _ 
         1 - Second(Now)) 
    Else 
     '10pm today 
     rTime.Value = Date + TimeSerial(22, 0, 0) 
    End If 
    Application.OnTime EarliestTime:=rTime.Value, Procedure:=PROC, Schedule:=True 

End Sub