在NASM中使用strstr（）的返回值？

Question

我想在NASM彙編程序中使用strstr C函數，但似乎無法使其正確打印出來。我嘗試了多種變化，但我想我可能會誤解NASM如何從C返回指針值，因爲我在printf或'（null）'中返回空行。爲什麼我無法獲得正確的印刷回報值？有些人可以幫我填補嗎？

section .data 

    str1 db "Here is some text with a word",0x0A,0x00 
    str2 db "text",0x0A, 0x00 
    strFmt db "%s",0x0A,0x00 

    global _start 
    extern printf 
    extern strstr 

section .text 

_start: 

    push ebp 
    mov ebp, esi 

    push str2 
    push str1 
    call strstr 
    add esp, 8 

    mov dword [myString], eax 

    push dword [myString] 
    push strFmt 
    call printf 
    add esp, 8 

_exit: 
    mov ebx, 0 
    mov eax, 1 
    int 0x80 

Answer 1

主要問題是搜索字符串中的0x0A。它是字符串的一部分，因爲終止null之前的所有內容都是它的一部分。它必須單獨列出，因爲C-style escape sequences內部的字符串不會被彙編程序解析。 strstr將不會找到「test \ n」。刪除0x0A和strstr將找到搜索字符串。

正如科迪格雷提到的，與mov ebp, esi塊是奇怪的 - 你可能意味着慣用的mov ebp, esp。而且，這個例子中並不需要。直接與myString -just push eax間接也是多餘的。

printf首先將輸出寫入緩衝區。您通過系統調用int 80h退出程序。這個調用會破壞包括printf緩衝區在內的所有進程。所以緩衝區不會被輸出。有兩種方法來解決這個問題：

1）使用C函數exit而不是系統調用：

section .data 
    str1 db "Here is some text with a word",0x0A,0x00 
    str2 db "text",0x00 
    strFmt db "%s",0x0A,0x00 

global _start 
extern printf, strstr, exit 

section .text 

_start: 

    push str2 
    push str1 
    call strstr 
    add esp, 8 

    push eax 
    push strFmt 
    call printf 
    add esp, 8 

_exit: 
    push 0 
    call exit 

2）調用添加到C函數fflush：

section .data 
    str1 db "Here is some text with a word",0x0A,0x00 
    str2 db "text",0x00 
    strFmt db "%s",0x0A,0x00 

global _start 
extern printf, strstr, fflush 

section .text 

_start: 

    push str2 
    push str1 
    call strstr 
    add esp, 8 

    push eax 
    push strFmt 
    call printf 
    add esp, 8 

    push 0 
    call fflush 

_exit: 
    mov ebx, 0 
    mov eax, 1 
    int 0x80