無法使用NEXT_SIBLING的方法或使用XML ::嫩枝

Question

twig_handlers next_elt我還是新的使用XML::Twig。

從主程序我期待的元素與屬性@method="create"

在子程序player，我想找到屬性@method="modify"的下一個元/兄弟。

這些方法都失敗子程序player與錯誤input.xwo的Can't call method "gi" on an undefined value

my $modif1=$valeur->next_sibling('[@method="modify"]') 

my $modif2=$valeur->next_elt('[@method="modify"]')->parent 

例子：

<top id="World"> 

    <middle id="France" method="create"> 
    </middle> 

    <middle id="Germany" method="modify"> 
    </middle> 

</top> 

我簡單的代碼：

#!/bin/perl -w 
use warnings; 
use XML::Twig; 

my $twig= new XML::Twig( 
    twig_handlers => { 
    '[@method="create"]' => \&player 
    } 
);      

$twig->parsefile("input.xwo"); 
$twig->purge; 

sub player { 

    my ($twig, $valeur) = @_;      

    my $modif1 = $valeur->next_sibling('[@method="modify"]'); 
    my $modif2 = $valeur->next_elt('[@method="modify"]')->parent; 
    print "\nnextELT=" . $modif->gi . "\n"; 
} 

Answer 1

請總是use strict在您的程序的頂部，並在第一次使用時使用my聲明變量。在use warnings和-w命令行選項中都沒有意義。第一個是可取的。

當調用<middle method="create">元素的樹枝處理程序時，您需要的同級，<middle method="modify">尚未處理。它不能被找到，因爲它還沒有在XML::Twig解析樹中。

必須要麼讀取整個XML結構和事後處理它，或寫一個處理程序包圍都的create和modify元素的元素。

這個程序做了後者。

use strict; 
use warnings; 

use XML::Twig; 

my $twig= XML::Twig->new(
    twig_handlers => { 
    top => \&player 
    } 
);      

$twig->parsefile('input.xwo'); 
$twig->purge; 

sub player { 

    my ($twig, $valeur) = @_;     

    my $create = $valeur->first_child('[@method="create"]'); 
    return unless $create; 

    my $modify = $create->next_sibling('[@method="modify"]'); 
    return unless $modify; 

    printf "\nnextELT = %s\n", $modify->gi; 

    $twig->purge; 
} 

---

更新

這種替代讀取整個XML樹，並從中提取後的數據。它開始通過尋找樹中的所有元素有method屬性等於'create'，然後發現他們每個人以下的兄弟姐妹與'modify'一個method屬性。

use strict; 
use warnings; 

use XML::Twig; 

my $twig= XML::Twig->new; 

$twig->parsefile('input.xwo'); 

my @creates = $twig->get_xpath('//*[@method="create"]'); 

foreach my $create (@creates) { 
    my $modify = $create->next_sibling('[@method="modify"]'); 
    next unless $modify; 
    printf "\nnextELT = %s\n", $modify->gi; 
}