我想獲得所有作者已經超過3件作品的列表 - DBpedia Sparql

Question

我想要獲得已完成3件或更多作品（在DBpedia中）的所有作者的列表。 http://dbpedia.org/sparql

基本代碼

select (count(?work) as ?totalWork), ?author 
Where 
{ 
    ?work dbo:author ?author. 
} 
GROUP BY ?author 

我得到每個作家作品的完成總量：

我的例子能上運行。但是，當我嘗試過濾僅顯示具有超過3件作品的作者列表時。我得到錯誤：

我試着HAVING關鍵字或使用FILTER關鍵字。

使用過濾器

select (count(?work) as ?tw), ?author 
Where 
{ 
    ?work dbo:author ?author. 
    FILTER (?work > 3). 
} 
GROUP BY ?author 

error: Virtuoso 22023 Error VECDT: SR066: Unsupported case in CONVERT (INTEGER -> IRI_ID) 

使用HAVING關鍵字

select (count(?work) as ?tw), ?author 
Where 
{ 
    ?work dbo:author ?author. 
} 
GROUP BY ?author 
HAVING (?tw > 3) 

Virtuoso 37000 Error SP031: SPARQL compiler: Variable ?tw is used in the result set outside aggregate and not mentioned in GROUP BY clause 

Answer 1

使用HAVING是正確的，但有一個limitation in SPARQL with indirectly referring to aggregates。

這一個工程：

SELECT (count(?work) as ?tw) ?author 
WHERE 
{ 
    ?work dbo:author ?author. 
} 
GROUP BY ?author 
HAVING (count(?work) > 3) 

Answer 2

使用HAVING

除了AKSW的答案 - https://github.com/openlink/virtuoso-opensource/issues/254。

使用濾紙的

你應該寫這樣的事情：

SELECT * 
WHERE 
{ 
    { 
    SELECT ?author (COUNT(?work) AS ?tw) 
    WHERE 
    { 
    ?work dbo:author ?author. 
    } GROUP BY ?author 
    } FILTER (?tw > 3) 
} 

Answer 3

HAVING (?tw > 3)是正確的SPARQL。 HAVING由於SELECT歸因於作業後的過濾器，因此?tw是可見的，並且在投影之前。

(prefix ((dbo: <http://purl.org/dc/elements/1.1/>)) 
    (project (?tw ?author) 
     (filter (> ?tw 3) 
     (extend ((?tw ?.0)) 
      (group (?author) ((?.0 (count ?work))) 
      (bgp (triple ?work dbo:author ?author))))))) 

其中?.0是count分配。