Excel VBA - 宏運行但不起作用

Question

我是Excel VBA新手，這是我的第一個宏，所以請原諒我，如果我犯了一個非常明顯的錯誤。我有以下代碼與工作表進行比較，如果找到匹配項，則在其中一張工作表上做筆記。它沒有錯誤地運行，但沒有做出改變。我看不出我出錯的地方。先謝謝您的幫助。

Sub invalid() 

Dim i As Integer 
Dim j As Integer 

Dim main As Worksheet 
Dim invalid As Worksheet 

i = 2 
Set main = ThisWorkbook.Worksheets(1) 
Set invalid = ThisWorkbook.Worksheets(2) 

Do 
    j = 2 
    Do 
     If LCase$(invalid.Cells(i, 1).Value) = LCase$(main.Cells(j, 13).Value) Then 
      main.Cells(j, 14).Value = "Invalid Email" 
     End If 
     j = j + 1 
    Loop While main.Cells(j, 2) = Not Null 
    i = i + 1 
Loop While invalid.Cells(i, 2) = Not Null 


End Sub 

Answer 1

試試這個，它消除了環路的一個：

Sub invalid() 

Dim i As Long 
Dim j As Long 
Dim lRow As Long 
Dim main As Worksheet 
Dim invalid As Worksheet 

Set main = ThisWorkbook.Worksheets(1) 
Set invalid = ThisWorkbook.Worksheets(2) 
lRow = main.Cells(main.Rows.Count, 13).End(xlUp).Row 

For i = 2 To lRow 
    j = 0 
    On Error Resume Next 
    j = Application.WorksheetFunction.Match(main.Cells(i, 13), invalid.Range("A:A"), 0) 
    On Error GoTo 0 
    If j > 0 Then main.Cells(i, 14) = "Invalid Email" 
Next i 

End Sub