使用XPath生成XPath

Question

我有兩種不同類型的XML文檔（一種是a.xml &另一種是b.xml）。文檔a.xml，是我的主要源文件，我必須運行查詢。文檔b.xml包含從a.xml獲取記錄的所有可能的信息。

文件：«A.XML»

<rs> 
    <r id="r1"> 
     <f0>typeA</f0> 
     <f1>contains value1, value2 and value3</f1> 
    </r> 
    <r id="r2"> 
     <f0>typeB</f0> 
     <f1>contains value4 and value7</f1> 
    </r> 
    <r id="r3"> 
     <f0>typeA</f0> 
     <f1>contains value2 and value5</f1> 
    </r> 
    <r id="r4"> 
     <f0>typeC</f0> 
     <f1>contains value1 and value6</f1> 
    </r> 
    <r id="r5"> 
     <f0>typeA</f0> 
     <f1>contains value5</f1> 
    </r> 
    <r id="r6"> 
     <f0>typeC</f0> 
     <f1>contains value1, value2 and value3</f1> 
    </r> 
</rs> 

---

文件：«B.XML»

<?xml version="1.0"?> 
<qs> 
    <q id="q1"> 
     <i0>typeA</i0> 
     <i1>value1|value2|value3</i1> 
     <i2>value18|value35</i2> 
     <i3>value1|value7</i3> 
    </q> 
    <q id="q2"> 
     <i0>typeB</i0> 
     <i1>value2|value7</i1> 
     <i2>value9|value20</i2> 
     <i3>value4</i3> 
    </q> 
</qs> 

---

現在我想生成動態XPath selector strings基於b.xml的值存儲在文檔c.xml中。它看起來像：

文件c.xml

<xps> 
    <xp id="q1"> 
     <t1>/rs/r[contains(f0,'typeA') 
       and contains(f1,'value1') 
       and contains(f1,'value2') 
       and contains(f1,'value3')]</t1> 
     <t2>/rs/r[contains(f0,'typeA') 
       and contains(f1,'value18') 
       and contains(f1,'value35')]</t2> 
     <t3>/rs/r[contains(f0,'typeA') 
       and contains(f1,'value1') 
       and contains(f1,'value7')]</t3> 
    </xp> 
    <xp id="q2"> 
     <t1>/rs/r[contains(f0,'typeB') 
       and contains(f1,'value2') 
       and contains(f1,'value7')]</t1> 
     <t2>/rs/r[contains(f0,'typeA') 
       and contains(f1,'value9') 
       and contains(f1,'value20')]</t2> 
     <t3>/rs/r[contains(f0,'typeA') 
       and contains(f1,'value4')]</t3> 
    </xp> 
</xps> 

---

如果有人在這裏有任何想法，如何做到在XSLT 1.0版本的工作。提前致謝。

Answer 1

這裏是XSLT 1.0的解決方案：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
    <xsl:output method="xml" encoding="utf-8" indent="yes"/> 

    <xsl:template match="@*|text()" /> 

    <xsl:template match="/"> 
     <xps> 
      <xsl:apply-templates/> 
     </xps> 
    </xsl:template> 

    <xsl:template match="q"> 
     <xp id="{@id}"> 
      <xsl:apply-templates/> 
     </xp> 
    </xsl:template> 

    <xsl:template match="*[starts-with(name(), 'i')][not(self::i0)]"> 
     <xsl:element name="t{substring-after(name(), 'i')}"> 
      <xsl:text>/rs/r[contains(f0, '</xsl:text> 
      <xsl:value-of select="preceding-sibling::i0"/> 
      <xsl:text>')</xsl:text> 
      <xsl:call-template name="more-conditions"> 
       <xsl:with-param name="list" select="."/> 
      </xsl:call-template> 
      <xsl:text>]</xsl:text> 
     </xsl:element> 
    </xsl:template> 

    <xsl:template name="more-conditions"> 
     <xsl:param name="list"/> 
     <xsl:param name="delimiter" select="'|'"/> 

     <xsl:choose> 
      <xsl:when test="contains($list, $delimiter)"> 
       <xsl:call-template name="more-conditions"> 
        <xsl:with-param name="list" select="substring-before($list, $delimiter)"/> 
       </xsl:call-template> 
       <xsl:call-template name="more-conditions"> 
        <xsl:with-param name="list" select="substring-after($list, $delimiter)"/> 
       </xsl:call-template> 
      </xsl:when> 
      <xsl:otherwise> 
       <xsl:text> and contains(f1, '</xsl:text> 
       <xsl:value-of select="$list"/> 
       <xsl:text>')</xsl:text> 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 

</xsl:stylesheet> 

適用於您的輸入文檔，它產生以下輸出：

<xps> 
    <xp id="q1"> 
     <t1>/rs/r[contains(f0, 'typeA') and contains(f1, 'value1') and contains(f1, 'value2') and contains(f1, 'value3')]</t1> 
     <t2>/rs/r[contains(f0, 'typeA') and contains(f1, 'value18') and contains(f1, 'value35')]</t2> 
     <t3>/rs/r[contains(f0, 'typeA') and contains(f1, 'value1') and contains(f1, 'value7')]</t3> 
    </xp> 
    <xp id="q2"> 
     <t1>/rs/r[contains(f0, 'typeB') and contains(f1, 'value2') and contains(f1, 'value7')]</t1> 
     <t2>/rs/r[contains(f0, 'typeB') and contains(f1, 'value9') and contains(f1, 'value20')]</t2> 
     <t3>/rs/r[contains(f0, 'typeB') and contains(f1, 'value4')]</t3> 
    </xp> 
</xps> 

我添加了一些空格。您可以根據需要修改轉換，但這應該讓您開始。

Answer 2

您不能在xslt版本1中將變量用作xpath選擇器，但可能有其他方法可以完成此任務。如果您提供的問題，而不是您想要的解決方案的人的想法也許能幫助:)