在後臺運行一個子例程，直到出現一個條件

Question

我該如何重寫這個以便info在後臺運行，直到$aw等於result？

#!/usr/bin/env perl 
use 5.12.0; 
use warnings; 
use Term::ReadLine; 

my $term = Term::ReadLine->new('something'); 
$term->ornaments(0); 

sub info { 
    # in the real script this runs some computations instead of the sleep 
    # and returns some information. 
    my ($time) = @_; 
    sleep $time; 
    return $time * 2; 
} 

my $value_returned_by_info = info(10); # run this in the background 
my $aw; 

$aw = $term->readline('User input: '); 
if ($aw eq 'result') { 
    # if info() is still running in the background: 
    # wait until info() returns because "$value_returned_by_info" is needed. 
    say $value_returned_by_info; 
} 
else { 
    # if info() is still running in the background: 
    # let info() in the background because "$value_returned_by_info" is not needed here. 
    say $aw; 
} 

$aw = $term->readline('User input: '); 
if ($aw eq 'result') { 
    # if info() is still running in the background: 
    # wait until info() returns because "$value_returned_by_info" is needed. 
    say $value_returned_by_info; 
} 
else { 
    # if info() is still running in the background: 
    # let info() in the background because "$value_returned_by_info" is not needed here. 
    say $aw; 
} 

$aw = $term->readline('User input: '); 
if ($aw eq 'result') { 
    # if info() is still running in the background: 
    # wait until info() returns because "$value_returned_by_info" is needed. 
    say $value_returned_by_info; 
} 
else { 
    # if info() is still running in the background: 
    # let info() in the background because "$value_returned_by_info" is not needed here. 
    say $aw; 
} 

say "End"; 

Answer 1

我同意user5402。提及在後臺運行和睡眠信息功能會引發很多問題。

我想知道，如果給定的輸入不正確，可能您正在尋找一種更爲簡潔的輸入重新提示方式。如果是這樣的話，那麼IO :: Prompter模塊可能適合你。

#!/usr/bin/env perl 

use 5.10.0; 
use strict; 
use warnings; 
use IO::Prompter; 

sub info { 
    my ($time) = @_; 
    sleep $time; 
    return $time * 2; 
} 

my $expect = info(10); 
my $aw; 

PROMPT: 
{ 
    $aw = IO::Prompter::prompt('Enter number', -i); 

    if ($aw eq $expect) { 

     say "$aw :)"; 
    } 
    else { 

     say "$aw :("; 

     redo PROMPT; 
    } 
} 

say "End"; 

Answer 2

如果info可以在一個單獨的進程中運行，那麼你可以只使用fork。否則，你將不得不使用perl的線程版本。

使用fork的例子：

sub start_info { 
    my @params = @_; 
    my $pipe; 
    my $pid = open($pipe, "-|"); 

    if (!$pid) { 
    # this code will run in a sub-process 
    # compute $result from @params 
    # and print result to STDOUT 
    sleep(10); 
    my $result = "p = $params[0] - pid $$"; 
    print $result; 
    exit(0); 
    }; 

    my $r; 
    return sub { 
    return $r if defined($r); 
    $r = <$pipe>; # read a single line 
    waitpid $pid, 0; 
    $r; 
    }; 
} 

sub prompt { 
    print "Hit return: "; 
    <STDIN>; 
} 

my $info1 = start_info(4); 
prompt(); 
print "result = ", $info1->(), "\n"; 

my $info2 = start_info(30); 
prompt(); 
print "result = ", $info2->(), "\n";