如何使用gnuplot創建徑向圖？

Question

可能重複：
How to get a radial(polar) plot using gnu plot?

我想徑向（極）地塊使用gnuplot的（即圓座標系（r，THETA）:!

這裏我已經使用的值：

如何使用gnu-plot得到這樣的情節？如果我拿正值，說3400,5300,4700等等......我必須能夠以同樣的情節將他們繪製成不會令人困惑的樣子。是否有一個gnu-plot命令直接提到半徑和theta而不是x和y座標來獲得這樣一個徑向圖？

在此先感謝

Answer 1

可能重複：here

我能想到的是隻有這樣，才能使用

set ytics ("-1000" 1000, "-2000" 2000, "-3000" 3000, "-4000" 4000, "-5000" 5000, "-6000" 6000) 

所以不是this問題的答案都使用這個腳本（僅此時間沒有評論）：

unset border 
set polar 
set angles degrees 

set style line 10 lt 1 lc 0 lw 0.3 

set grid polar 60 
set grid ls 10 

set xrange [-6000:6000] 
set yrange [-6000:6000] 

set xtics axis 
set ytics axis 

set xtics scale 0 
set xtics ("" 1000, "" 2000, "" 3000, "" 4000, "" 5000, "" 6000) 
set ytics ("-1000" 1000, "-2000" 2000, "-3000" 3000, "-4000" 4000, "-5000" 5000,  "-6000" 6000) 

set size square 

set key lmargin 

set_label(x, text) = sprintf("set label '%s' at (6500*cos(%f)), (6500*sin(%f))    center", text, x, x) 

eval set_label(0, "0") 
eval set_label(60, "60") 
eval set_label(120, "120") 
eval set_label(180, "180") 
eval set_label(240, "240") 
eval set_label(300, "300") 

set style line 11 lt 1 lw 2 pt 2 ps 2 

plot "-" u 1:(-1*$2) t "Max strain" w lp ls 11 
0 -3400 
60 -5300 
120 -4700 
180 -3800 
240 -4100 
300 -3100 
360 -3400 
e