命令行：枚舉所有「運行」註冊表項子項+數據

Question

我想創建一個cmd腳本，其中包含所有子項，其中列出了 HKEY_USERS * \ Software \ Microsoft \ Windows \ CurrentVersion \ Run 。

這是我迄今爲止，但它不工作..變量沒有設置？

setlocal ENABLEEXTENSIONS 
FOR /F "usebackq " %%A IN (`REG QUERY HKU`) DO (
    set "datareg=%%A\Software\Microsoft\Windows\CurrentVersion\Run" 
    @echo %datareg% >> "%userprofile%\desktop\runregistery.txt" 
) 

Answer 1

你可以做你在不使用set隨後echo單行想要什麼。

---

要導出HKEY_CURRENT_USER的密鑰列表，您可以使用以下批處理文件。

TEST.CMD：

@echo off 
for /f "usebackq skip=2" %%a in (`reg query HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run`) do echo %%a>> "%userprofile%\desktop\runregistery.txt" 

輸出示例：

f.lux 
PureText 
EPSON 
WinPatrol 

---

如果你想鍵和HKEY_CURRENT_USER值，然後使用reg export：

reg export HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Run > reg.out 

例如輸出：

Windows Registry Editor Version 5.00 

[HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run] 
"f.lux"="\"C:\\Users\\DavidPostill\\AppData\\Local\\FluxSoftware\\Flux\\flux.exe\" /noshow" 
"PureText"="\"C:\\apps\\PureText\\PureText.exe\"" 
"EPSON Stylus Photo RX560 Series"="C:\\Windows\\system32\\spool\\DRIVERS\\x64\\3\\E_IATIBPE.EXE /FU \"C:\\Windows\\TEMP\\E_S8843.tmp\" /EF \"HKCU\"" 
"WinPatrol"="C:\\apps\\WinPatrol\\winpatrol.exe -expressboot" 

---

要導出爲HKEY_USERS您可以使用下面的批處理文件列表鍵。

TEST.CMD：

@echo off 
Setlocal EnableDelayedExpansion 
for /f "usebackq" %%a in (`reg query HKEY_USERS`) do (
    set _user=%%a 
    for /f "usebackq" %%b in (`reg query !_user!\SOFTWARE\Microsoft\Windows\CurrentVersion\Run 2^> nul`) do (
    echo %%b>> "%userprofile%\desktop\runregistery.txt" 
    ) 
) 

輸出示例：

HKEY_USERS\S-1-5-19\SOFTWARE\Microsoft\Windows\CurrentVersion\Run 
Sidebar 
HKEY_USERS\S-1-5-20\SOFTWARE\Microsoft\Windows\CurrentVersion\Run 
Sidebar 
HKEY_USERS\S-1-5-21-1699878757-1063190524-3119395976-1000\SOFTWARE\Microsoft\Windows\CurrentVersion\Run 
f.lux 
PureText 
EPSON 
WinPatrol