在Clojure中分區分區？

Question

以下是一些值。每個都是一系列的升序（或其他分組）值。

(def input-vals [[[1 :a] [1 :b] [2 :c] [3 :d] [3 :e]] 
      [[1 :f] [2 :g] [2 :h] [2 :i] [3 :j] [3 :k]] 
      [[1 :l] [3 :m]]]) 

我可以按價值分割它們。

=> (map (partial partition-by first) input-vals) 
    ((([1 :a] [1 :b]) ([2 :c]) ([3 :d] [3 :e])) (([1 :f]) ([2 :g] [2 :h] [2 :i]) ([3 :j] [3 :k])) (([1 :l]) ([3 :m]))) 

但是，我得到了3個分區序列。我想要一個單獨的分區組序列。

我想要做的是返回單個惰性序列（可能）是連接的各個分區的惰性序列。例如我想產生這樣：

((([1 :a] [1 :b] [1 :f] [1 :l]) ([2 :c] [2 :g] [2 :h] [2 :i]) ([3 :d] [3 :e] [3 :j] [3 :k] [3 :m]))) 

請注意，並非所有的值出現在所有序列（有第三矢量沒有2）。

這當然是我的問題的簡化。真實的數據是來自非常大的文件的一組惰性流，所以什麼都不能實現。但我認爲上述問題的解決方案是解決我的問題。

隨意編輯標題，我不太確定如何表達它。

Answer 1

試試這個恐怖：

(defn partition-many-by [f comp-f s] 
    (let [sorted-s (sort-by first comp-f s) 
     first-list (first (drop-while (complement seq) sorted-s)) 
     match-val (f (first first-list)) 
     remains (filter #(not (empty? %)) 
         (map #(drop-while (fn [ss] (= match-val (f ss))) %) 
          sorted-s))] 
    (when match-val 
     (cons 
     (apply concat 
      (map #(take-while (fn [ss] (= match-val (f ss))) %) 
       sorted-s)) 
     (lazy-seq (partition-many-by f comp-f remains)))))) 

它也可能會被提高，以除去雙重值檢查（take-while和drop-while）。

用法示例：

(partition-many-by identity [[1 1 1 1 2 2 3 3 3 3] [1 1 2 2 2 2 3] [3]]) 

=> ((1 1 1 1 1 1) (2 2 2 2 2 2) (3 3 3 3 3 3)) 

Answer 2

我不知道我是否以下，但你可以faltten結果順序是這樣的：

(flatten (partition-by identity (first input-vals))) 

clojure.core /扁平
（[X]）
接受任何順序事物（列表，向量，
等）的嵌套組合，並將其內容作爲單個平坦序列返回。
（flatten nil）返回一個空序列。

你可以使用實現嗎？函數來測試一個序列是否懶惰。

Answer 3

user> (def desired-result '((([1 :a] [1 :b] [1 :f] [1 :l]) 
          ([2 :c] [2 :g] [2 :h] [2 :i]) 
          ([3 :d] [3 :e] [3 :j] [3 :k] [3 :m])))) 
#'user/desired-result 

user> (def input-vals [[[1 :a] [1 :b] [2 :c] [3 :d] [3 :e]] 
         [[1 :f] [2 :g] [2 :h] [2 :i] [3 :j] [3 :k]] 
         [[1 :l] [3 :m]]]) 
#'user/input-vals 

user> (= desired-result (vector (vals (group-by first (apply concat input-vals))))) 
true 

我改變了輸入丘壑稍微糾正什麼，我認爲是一個拼寫錯誤，如果它是不是一個錯誤，我可以更新我的代碼，以適應結構比較鬆散。

使用->>（線程最後）宏，我們可以有相當的代碼更可讀的形式：

user> (= desired-result 
     (->> input-vals 
      (apply concat) 
      (group-by first) 
      vals 
      vector)) 
true 

Answer 4

讓我們把這個有趣和使用無限長度的序列爲我們輸入

(def twos (iterate #(+ 2 %) 0)) 
(def threes (iterate #(+ 3 %) 0)) 
(def fives (iterate #(+ 5 %) 0)) 

我們需要懶洋洋地合併。我們要求一個比較器，以便我們也可以應用於其他數據類型。

(defn lazy-merge-by 
([compfn xs ys] 
    (lazy-seq 
    (cond 
     (empty? xs) ys 
     (empty? ys) xs 
     :else (if (compfn (first xs) (first ys)) 
       (cons (first xs) (lazy-merge-by compfn (rest xs) ys)) 
       (cons (first ys) (lazy-merge-by compfn xs (rest ys))))))) 
    ([compfn xs ys & more] 
    (apply lazy-merge-by compfn (lazy-merge-by compfn xs ys) more))) 

測試

(take 15 (lazy-merge-by < twos threes fives)) 
;=> (0 0 0 2 3 4 5 6 6 8 9 10 10 12 12) 

我們可以（懶惰）由值分區如果需要

(take 10 (partition-by identity (lazy-merge-by < twos threes fives))) 
;=> ((0 0 0) (2) (3) (4) (5) (6 6) (8) (9) (10 10) (12 12)) 

現在，回到樣品輸入

(partition-by first (apply lazy-merge-by #(<= (first %) (first %2)) input-vals)) 
;=> (([1 :a] [1 :b] [1 :f] [1 :l]) ([2 :c] [2 :g] [2 :h] [2 :i]) ([3 :d] [3 :e] [3 :j] [3 :k] [3 :m])) 

根據需要少一個多餘的一組外部括號。

Answer 5

(partition-by first (sort-by first (mapcat identity input-vals)))