在Access 2010中構建搜索表格

Question

我正在嘗試爲搜索2010進行搜索客戶表單。

我喜歡根據查詢搜索具有選項組。我做了一個搜索查詢尋找名字或姓氏。兩個文本框也出現在窗體上填寫查詢輸入（姓和名）

我需要選項組，以便我可以選擇結果名稱作爲預訂目的。

在過去，我使用子窗體和複選框做了一個間接的方法。 然後將兩個結果加載到子窗體和複選框（查詢）上，以便用戶只需在複選框上進行選擇。但是這一次我希望選項成爲查詢結果本身！請幫忙。

Answer 1

下面是一個使用一個列表框的簡單示例：

表：客戶端

ID - 自動編號
名字 - 文本（255）
姓 - 文本（255）
電子郵件 - 文本（255）

測試數據：

ID LastName FirstName  Email 
-- ---------- -------------- ------------------ 
1 Thompson Gord   gord@example.com 
2 Loblaw  Bob    bob@example.com 
3 Kingsley Hank   hank@example.com 
4 Thompson Hunter S.  hunter@example.com 
5 Squarepants Spongebob  ss@example.com 
6 O'Rourke P. J.   pj@example.com 
7 Aldrin  Edwin "Buzz" buzz@example.com 

表格佈局：這種形式

VBA模塊：

Option Compare Database 
Option Explicit 

Private Sub Form_Load() 
Me.lstSearchResults.RowSource = "" 
End Sub 

Private Sub btnSearch_Click() 
Me.lstSearchResults.SetFocus 
Me.lstSearchResults.Value = Null 
Me.lstSearchResults.RowSource = _ 
     "SELECT ID, LastName, FirstName FROM Clients " & _ 
      "WHERE LastName LIKE ""*" & DQ(Me.txtSearchLastName.Value) & _ 
       "*"" AND FirstName LIKE ""*" & DQ(Me.txtSearchFirstName.Value) & "*""" 
End Sub 

Private Function DQ(s As Variant) As String 
' double-up double quotes for SQL 
DQ = Replace(Nz(s, ""), """", """""", 1, -1, vbBinaryCompare) 
End Function 

Private Sub btnLookupEmail_Click() 
If IsNull(Me.lstSearchResults.Value) Then 
    Me.txtEmail.Value = "" 
Else 
    Me.txtEmail.Value = DLookup("Email", "Clients", "ID=" & Me.lstSearchResults.Value) 
End If 
End Sub 

當窗體第一次打開，一切都是空的。

鍵入 「湯普森」（不帶引號），然後單擊btnSearch填充列表框與客戶WHERE LastName LIKE "*thompson*"。 （如果你看一下代碼，你會看到，它也將匹配名字，如果你提供一個）。

選擇在列表框中的一個項目，然後單擊btnLookupEmail和電子郵件地址顯示在下面的文本框中。