ODS PDF - 輸出的兩列在單個頁面上被一列輸出中斷

我試圖爲請求者創建一個輸出，該請求者希望我採用預先存在的報告，該報告來自單個頁面上的兩列，並且中斷它在單個頁面上分爲不同的小節，他們希望在新小節開始的頁面中間用新標題表示。ODS PDF - 輸出的兩列在單個頁面上被一列輸出中斷

我有現在的問題是：

ods pdf file=_pdf_ newfile=none startpage=no columns=2 notoc contents=no 
style=swsp; 

ods text = 'EMPLOYER RENEWAL DATA'; 

proc report data=renewal_data; 
... 
run; 

ods startpage=now; 
ods text='FINANCIAL DATA (FULL PROGRAM YEAR)'; 
proc report data=financial_data_total; 
    ... 
run; 

ods startpage=now; 
title1 '$ACA_YR_STR. ACADEMIC YEAR DATA'; 
footnote; 

ods text='APPLICANT DATA'; 
... 
run;

我要的是有一個章節標題，其中第二ODS起始頁=現在所在的是將整個頁面作爲一個欄的頁面，但隨後返回到頁面其餘部分的兩列。

謝謝！

來源

2015-10-14 Kristopher Snyder

因此，你會有像頁面部分的兩列布局，然後在兩列的部分標題，然後兩列的佈局半路？也許一張照片在這裏會有所幫助。另外 - 這是什麼版本的SAS？新版本有'ODS LAYOUT'功能更強大的工具。 – Joe

是的，這正是我期望做的。我們正在使用9.4。抱歉應該提到這一點。 –

如果你有SAS 9.4（也可能是9.3），你可以使用ODS LAYOUT來實現這一點很容易。您需要創建網格佈局，然後將您的標題更改爲另一個ODS TEXT（您當然可以像標題一樣）。標題與PROCs，而不是自己，所以如果你真的使用標題它會出現在下一個PROC REPORT去，而不是在自己的區域。

這裏有一個準系統的例子，可能會讓你開始。有關更多信息，請參閱ODS REGION和ODS LAYOUT文檔。注意，這是生產中的東西，但也處於積極的發展階段，所以不同版本的SAS（包括更新版本）可能會改變其中一些工作方式（儘管希望不會破壞以前存在的功能，但誰知道）。

ods pdf file="c:\temp\test.pdf" startpage=no newfile=none notoc contents=no 
style=swsp; 
options obs=10; 

ods layout gridded columns=2 rows=3; 
ods region row=1 column=1; 
ods text = 'CLASS DATA'; 

proc report data=sashelp.class; 
columns name age; 
run; 

ods region row=1 column=2; 
ods text='CAR DATA'; 
proc report data=sashelp.cars; 
    columns make model; 
run; 

ods region column_span=2 row=2 column=1; 
ods text='ACROSS THE WHOLE PAGE NOW'; 
footnote; 

ods region row=3 column=1; 
ods text='NOT ACROSS WHOLE PAGE FOR THIS PART'; 
proc report data=sashelp.baseball; 
    columns name team; 
run; 
ods layout end; 
ods pdf close;

來源

2015-10-14 17:05:07 Joe

ODS PDF - 輸出的兩列在單個頁面上被一列輸出中斷

回答

相關問題