如何編寫一個返回相鄰對的列表的Clojure函數？

Question

我想寫一個函數adjacents，它返回一個序列的相鄰對的向量。所以(adjacents [1 2 3])將返回[[1 2] [2 3]]。

(defn adjacents [s] 
    (loop [[a b :as remaining] s 
      acc []] 
    (if (empty? b) 
     acc 
     (recur (rest remaining) (conj acc (vector a b)))))) 

我目前的實施適用於字符串的序列，但與整數或字符REPL輸出這個錯誤：

IllegalArgumentException Don't know how to create ISeq from: java.lang.Long clojure.lang.RT.seqFrom (RT.java:494) 

Answer 1

這裏的問題是在(adjacents [1 2 3])第一次評估環路，a勢必1和b至2。然後你問是否b是empty?。但empty?對序列起作用，而b不是序列，而是Long，即2。你可以使用此情況下這裏的謂詞是nil?：

user=> (defn adjacents [s] 
    #_=> (loop [[a b :as remaining] s acc []] 
    #_=>  (if (nil? b) 
    #_=>  acc 
    #_=>  (recur (rest remaining) (conj acc (vector a b)))))) 
#'user/adjacents 
user=> (adjacents [1 2 3 4 5]) 
[[1 2] [2 3] [3 4] [4 5]] 

但是，正如@amalloy指出，如果你有合法的nil在你的數據，這可能無法得到期望的結果：

user=> (adjacents [1 2 nil 4 5]) 
[[1 2]] 

請參閱他對使用列表的建議實現的評論。

注意，Clojure的partition可以用來做這項工作沒有定義自己的危險：

user=> (partition 2 1 [1 2 3 4 5]) 
((1 2) (2 3) (3 4) (4 5)) 
user=> (partition 2 1 [1 2 nil 4 5]) 
((1 2) (2 nil) (nil 4) (4 5)) 

Answer 2

這是我簡單的回答。一切都變成了一個向量，但它適用於所有的序列。

(defn adjacent-pairs [s] 
    {:pre [(sequential? s)]} 
    (map vector (butlast s) (rest s))) 

測試：

user=> (defn adjacent-pairs [s] (map vector (butlast s) (rest s))) 
#'user/adjacent-pairs 
user=> (adjacent-pairs '(1 2 3 4 5 6)) 
([1 2] [2 3] [3 4] [4 5] [5 6]) 
user=> (adjacent-pairs [1 2 3 4 5 6]) 
([1 2] [2 3] [3 4] [4 5] [5 6]) 
user=> 

這個答案很可能是比上面使用partition一個低效率的，但是。