Perl腳本從一個文件中刪除單詞到輸出文件

Question

林相當肯定這是非常基本的。但是我不知道Perl，只需要使用它一次。所以我感謝你的耐心。低於該

我想從一個單行刪除不需要的文本是在HTML：

<a target="_blank"   href="http://sharepoint/sites/cerner/quickreferenceguides/Documents/EXP001_Run_Printable_TCI_List.pdf" onmouseover="return overlib('This guide outlines the process for running a printable TCI List', CAPTION, 'TCI LIST');" onmouseout="return nd();">Run Printable TCI List (<i>Revised<i>)</a> 

所有我想被留下的是Run Printable TCI List (<i>Revised</i>)是在</a>之前結束的文本。我有大約500條這樣的線路，並且由於它們將來可以改變，所以創建一個程序是有意義的。下面是我的Perl代碼至今：

open (SEARK, 'C:\\HTMLsorter\\sources.txt'); 
open (OUTSEARK, '>C:\\HTMLsorter\\outseark.txt'); 
while(<SEARK>) { 
    chomp; 

    if ($_=~/<a target/) { 
    $_ =~ s/\<i>//g; 
    $_ =~ s/\<\/i>//g; 
    @itemsa = split(/>/); 
    @itemsb = split(/</, $itemsa[1]); 
    print OUTSEARK ("$itemsb[0]\n"); 
    } 
} 
close (SEARK); 
close (OUTSEARK); 

我敢肯定，你可以閱讀這只是說明那裏有要排序的500行，我打開一個叫sources.txt文件。輸出文件將是outseark.txt。到目前爲止，它會輸出這樣的：

Run Printable TCI List (Revised) 

這顯然是由於拆分瞄準和周圍的箭頭的一切。任何想法如何將斜體保留在括號內？要留下：

Run Printable TCI List (<i>Revised<i>) 

感謝您的期待。

Answer 1

你應該使用正確的HTML解析器，如HTML::TreeBuilder。該代碼是沒有更爲複雜，因爲這個程序演示

use strict; 
use warnings; 

use HTML::TreeBuilder; 

my $tree = HTML::TreeBuilder->new_from_file(*DATA); 

print $_->as_text, "\n" for $tree->look_down(_tag => 'a', target => qr/./); 

__DATA__ 
    <a target="_blank"   href="http://sharepoint/sites/cerner/quickreferenceguides/Documents/EXP001_Run_Printable_TCI_List.pdf" onmouseover="return overlib('This guide outlines the process for running a printable TCI List', CAPTION, 'TCI LIST');" onmouseout="return nd();">Run Printable TCI List (<i>Revised<i>)</a> 

輸出

Run Printable TCI List (Revised) 

---

編輯

要在您的例子中使用的文件這種技術，代碼看起來像這樣

use strict; 
use warnings; 

use HTML::TreeBuilder; 

my $tree = HTML::TreeBuilder->new_from_file('C:\HTMLsorter\sources.txt'); 

open my $out, '>', 'C:\HTMLsorter\outseark.txt' or die $!; 

print $out $_->as_text, "\n" for $tree->look_down(_tag => 'a', target => qr/./); 

---

編輯2

現在我更好地瞭解你需要什麼，我可以提供這種替代解決方案。它使用HTML::DOM模塊訪問HTML文檔的文檔對象模型，因爲獲得HTML::TreeBuilder所需的結果相對困難。

我也注意到，您的示例HTML包含<i>Revised<i>，顯然應該是<i>Revised</i>，並且我已經對此示例測試進行了更正。無論如何，Perl試圖按照瀏覽器解析錯誤的HTML，即使輸出錯誤也是可用的。

use strict; 
use warnings; 

use HTML::DOM; 

my $dom = HTML::DOM->new; 
$dom->parse_file('C:\HTMLsorter\sources.txt') or die $!; 

open my $out, '>', 'C:\HTMLsorter\outseark.txt' or die $!; 
print $out $_->innerHTML, "\n" for grep $_->attr('target'), $dom->getElementsByTagName('a'); 

輸出

（帶標籤校正）

Run Printable TCI List (<i>Revised</i>) 

（含原標籤）

Run Printable TCI List (<i>Revised<i>)</i></i> 

Answer 2

你可以在一個班輪中做到這一點。

cat inputfile|perl -ne 'if (s#<a\s+target[^>]+>(.+?)</a>##is){print "$1\n";}'>outputfile 

據工作：

echo '<a target="_blank"   href="http://sharepoint/sites/cerner/quickreferenceguides/Documents/EXP001_Run_Printable_TCI_List.pdf" onmouseover="return overlib('This guide outlines the process for running a printable TCI List', CAPTION, 'TCI LIST');" onmouseout="return nd();">Run Printable TCI List (<i>Revised<i>)</a> 
<a target="_blank"   href="http://sharepoint/sites/cerner/quickreferenceguides/Documents/EXP001_Run_Printable_TCI_List.pdf" onmouseover="return overlib('This guide outlines the process for running a printable TCI List', CAPTION, 'TCI LIST');" onmouseout="return nd();">Run Printable TCI List 1(<i>Revised<i>)</a> 
<a target="_blank"   href="http://sharepoint/sites/cerner/quickreferenceguides/Documents/EXP001_Run_Printable_TCI_List.pdf" onmouseover="return overlib('This guide outlines the process for running a printable TCI List', CAPTION, 'TCI LIST');" onmouseout="return nd();">Run Printable TCI List 2(<i>Revised<i>)</a> 
<a target="_blank"   href="http://sharepoint/sites/cerner/quickreferenceguides/Documents/EXP001_Run_Printable_TCI_List.pdf" onmouseover="return overlib('This guide outlines the process for running a printable TCI List', CAPTION, 'TCI LIST');" onmouseout="return nd();">Run Printable TCI List 3(<i>Revised<i>)</a>'|\ 
perl -ne 'if (s#<a\s+target[^>]+>(.+?)</a>##is){print "$1\n";}' 

Run Printable TCI List (<i>Revised<i>) 
Run Printable TCI List 1(<i>Revised<i>) 
Run Printable TCI List 2(<i>Revised<i>) 
Run Printable TCI List 3(<i>Revised<i>) 

Answer 3

#!/usr/bin/perl 
use strict; 
use warnings; 

open IFH, '<myfile.txt'; 
open OFH, '>output.txt'; 

while (<IFH>) { 
    if (/<a\s+target.*?>(.*?)<\/a>/i) 
    { 
    $_ = $1; 
    s/<.*?>//g; 
    print OFH "$_\n"; 
    } 
} 

close IFH; 
close OFH;