類型不匹配13錯誤 - 引用對象

Question

我創建了一個子例程來將工作表中的所有單元格存儲在名爲「CNrng3」的對象中。

Sub GetCLRange() 
Dim CLrng1 As Range 
Dim CLrng2 As Range 
Sheets("Cancel").Activate 
Set CLrng1 = Cells.Find("*", [a1], , , xlByRows, xlPrevious) 
Set CLrng2 = Cells.Find("*", [a1], , , xlByColumns, xlPrevious) 
If Not CLrng1 Is Nothing Then 
    Set CLrng3 = Range([a1], Cells(CLrng1.Row, CLrng2.Column)) 
Application.Goto CLrng3 
Else 
    MsgBox "sheet is blank", vbCritical 
End If 
End Sub 

現在，我要引用這個對象來創建與數據樞軸：

ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:= _ 
    CLrng3.Cells, Version:=xlPivotTableVersion12).CreatePivotTable _ 
    TableDestination:="CancelSummary!R1C1", TableName:="CancelPivot", _ 
    DefaultVersion:=xlPivotTableVersion12 

的問題是，我得到「類型不匹配錯誤13」當我運行的這一部分代碼。有沒有人有一個想法，爲什麼我可能會收到這個錯誤，以及如何解決它？

謝謝！

Answer 1

如果試圖記錄與宏錄製的代碼，你將看到SourceRange希望看到作爲"Cancel!R1C1:R10C5"這樣的地址，其中包括工作表名稱

因此，而不是

SourceData:= CLrng3.Cells

試

SourceData:=(Clrng3.Parent.Name & "!" & Clrng3.Address)

which retur NS三個部分

1. 「取消」（如你的範圍的父項的名稱）
2. 「！」
3. 和類似A1：E10

給Cancel!A1:E10

Sub GetCLRange() 
    Dim CLrng1 As Range 
    Dim CLrng2 As Range 
    Dim Clrng3 As Range 
    Sheets("Cancel").Activate 
    Set CLrng1 = Cells.Find("*", [a1], , , xlByRows, xlPrevious) 
    Set CLrng2 = Cells.Find("*", [a1], , , xlByColumns, xlPrevious) 
    If Not CLrng1 Is Nothing Then 
     Set Clrng3 = Range([a1], Cells(CLrng1.Row, CLrng2.Column)) 
     ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:= _ 
              ("'" & Clrng3.Parent.Name & "'!" & Clrng3.Address), Version:=xlPivotTableVersion12).CreatePivotTable _ 
              TableDestination:="CancelSummary!R1C1", TableName:="CancelPivot", _ 
              DefaultVersion:=xlPivotTableVersion12 
     Application.Goto Clrng3 
    Else 
     MsgBox "sheet is blank", vbCritical 
    End If 
End Sub