antlr gated predicate

Question

這是一個來自Antlr superfluous Predicate required?的後續問題，我以簡化的方式說明了我的問題，但無法在此解決。
我有以下語法，當我刪除{true}?=>謂詞時，文本不再被識別。輸入字符串是MODULE main LTLSPEC H {} {} {o} FALSE;。請注意，尾部;未標記爲EOC，而是標記爲IGNORE。當我將{true}?=>添加到EOC規則;被標記爲EOC時。
我從antlr-v3.3和v3.4的命令行嘗試了這一點，沒有區別。在此先感謝，我感謝您的幫助。

grammar NusmvInput; 

options { 
    language = Java; 
}  
@parser::members{ 
public static void main(String[] args) throws Exception { 
    NusmvInputLexer lexer = new NusmvInputLexer(new ANTLRStringStream("MODULE main LTLSPEC H {} {} {o} FALSE;")); 
    NusmvInputParser parser = new NusmvInputParser(new CommonTokenStream(lexer)); 
    parser.specification(); 
    } 
}  
@lexer::members{ 
    private boolean inLTL = false; 
} 

specification : 
    module+ EOF 
    ; 
module : 
    MODULE module_decl  
    ; 

module_decl : 
    NAME parameter_list ; 
parameter_list 
    : (LP (parameter (COMMA parameter)*)? RP)? 
    ;  
parameter 
    : (NAME | INTEGER) 
    ;  
/************** 
*** LEXER 
**************/ 
COMMA 
    :{!inLTL}?=> ',' 
    ; 
OTHER 
    : {!inLTL}?=>('&' | '|' | 'xor' | 'xnor' | '=' | '!' | 
    '<' | '>' | '-' | '+' | '*' | '/' | 
     'mod' | '[' | ']' | '?') 
     ;  
RCP 
     : {!inLTL}?=>'}' 
     ;  
LCP 
     : {!inLTL}?=>'{' 
     ; 
LP 
    : {!inLTL}?=>'(' 
    ; 
RP 
    : {!inLTL}?=>')' 
    ; 
MODULE 
    : {true}?=> 'MODULE' {inLTL = false;} 
    ; 
LTLSPEC 
    : {true}?=> 'LTLSPEC' 
    {inLTL = true; skip(); } 
    ; 
EOC 
    : ';' 
    { 
     if (inLTL){ 
      inLTL = false; 
      skip(); 
     } 
    } 
    ; 
WS 
    : (' ' | '\t' | '\n' | '\r')+ {$channel = HIDDEN;} 
    ; 
COMMENT 
    : '--' .* ('\n' | '\r') {$channel = HIDDEN;} 
    ; 
INTEGER 
    : {!inLTL}?=> ('0'..'9')+ 
    ; 
NAME 
    :{!inLTL}?=> ('A'..'Z' | 'a'..'z') ('a'..'z' | 'A'..'Z' | '0'..'9' | '_' | '$' | '#' | '-')* 
    ; 
IGNORE 
    : {inLTL}?=> . {skip();} 
    ; 

Answer 1

似乎沒有MODULE和LTLSPEC前的謂語時，NAME得到優先於他們，即使這些令牌的NAME令牌中定義。不管這是設計還是錯誤，我都不知道。

然而，你試圖解決它的方式似乎相當複雜。據我所知，你似乎想要忽略（或跳過）以LTLSPEC開始並以分號結尾的輸入。爲什麼不這樣做，而不是：

specification : module+ EOF; 
module   : MODULE module_decl; 
module_decl : NAME parameter_list; 
parameter_list : (LP (parameter (COMMA parameter)*)? RP)?;  
parameter  : (NAME | INTEGER);  

MODULE : 'MODULE'; 
LTLSPEC : 'LTLSPEC' ~';'* ';' {skip();}; 
COMMA : ','; 
OTHER : ('&' | '|' | 'xor' | 'xnor' | '=' | '!' | 
      '<' | '>' | '-' | '+' | '*' | '/' | 
      'mod' | '[' | ']' | '?') 
     ;  
RCP  : '}';  
LCP  : '{'; 
LP  : '('; 
RP  : ')'; 
EOC  : ';'; 
WS  : (' ' | '\t' | '\n' | '\r')+ {$channel = HIDDEN;}; 
COMMENT : '--' .* ('\n' | '\r') {$channel = HIDDEN;}; 
INTEGER : ('0'..'9')+; 
NAME : ('A'..'Z' | 'a'..'z') ('a'..'z' | 'A'..'Z' | '0'..'9' | '_' | '$' | '#' | '-')*;