配置Gradle發佈源代碼和javadoc

Question

如何配置Gradle將源代碼和javadoc jar發佈到存儲庫？

Answer 1

下面的代碼添加到構建腳本：

task packageJavadoc(type: Jar, dependsOn: 'javadoc') { 
    from javadoc.destinationDir 
    classifier = 'javadoc' 
} 
task packageSources(type: Jar, dependsOn: 'classes') { 
    from sourceSets.main.allSource 
    classifier = 'sources' 
} 
artifacts { 
    archives packageJavadoc 
    archives packageSources 
} 

測試與搖籃1.10

Answer 2

保羅Fulgoni的回答用於爲直到我碰到了我的搖籃版本3.1工作。要獲得packageJavadoc任務與搖籃3.1工作，我發現我不得不做出點小文章，如下所示：

task packageJavadoc(type: Jar) { 
    from javadoc 
    classifier = 'javadoc' 
} 

Answer 3

2017年，搖籃4.0版：

apply plugin: 'maven' 
apply plugin: 'maven-publish' 

publishing { 
    publications { 
     mavenJava(MavenPublication) { 
      from components.java 

      artifact sourceJar 
      artifact packageJavadoc 
     } 
    } 
} 

javadoc { 
    source = sourceSets.main.allJava 
    classpath = configurations.compileClasspath 

    options 
    { 
    setMemberLevel JavadocMemberLevel.PUBLIC 
    setAuthor true 

    links "https://docs.oracle.com/javase/8/docs/api/" 
    } 
} 

task sourceJar(type: Jar) { 
    classifier = 'sources' 
    from sourceSets.main.allJava 
} 

task packageJavadoc(type: Jar) { 
    from javadoc 
    classifier = 'javadoc' 
} 

工程與gradle publish和gradle publishToMavenLocal