SQL Server 2008存儲過程執行問題

我會盡力詳細解釋問題。我寫了一個SP併成功執行。那就是：SQL Server 2008存儲過程執行問題

SET ANSI_NULLS ON 
GO 
SET QUOTED_IDENTIFIER ON 
GO 

ALTER PROCEDURE [dbo].[InvoiceReference] 

@StartDate DateTime = NULL, 
@EndDate DateTime = NULL, 
@DocumentType nvarchar(50) = NULL, 
@Partners nvarchar(MAX) = NULL, 
@PriceFrom numeric(19,6) = NULL, 
@PriceTo numeric(19,6) = NULL, 
@VATFrom numeric(19,6) = NULL, 
@VATTo numeric(19,6) = NULL, 

@PageNumber INT, 
@PageSize INT 

AS 
BEGIN SET NOCOUNT ON; 

    DECLARE @StartPage as int 
    DECLARE @EndPage as int 

    SET @StartPage = ((@PageNumber-1) * @PageSize) + 1; 
    SET @EndPage = @StartPage + (@PageSize) - 1; 


    WITH ResultSet As (select 

    ROW_NUMBER() OVER (order by d.DocumentID) AS 'RowNumber', 
    d.DocNumber, dt.Name as DocumentTypesName, d.Date, p.Name as PartnersName, dd.SalePrice, dd.VAT, (dd.SalePrice + dd.VAT) as TotalSum 

    from [dbo].[Documents] d join [dbo].[DocumentTypes] dt on d.TypeID = dt.TypeID 
          join [dbo].[Partners] p on d.PartnerID = p.PartnerID 
          join [dbo].[DocumentDetails] dd on d.DocumentID = dd.DocumentID 


    where ((@StartDate is null) or (d.Date >= @StartDate)) 
    and ((@EndDate is null) or (d.Date <= @EndDate)) 
    and ((@DocumentType is null) or (dt.Name = @DocumentType)) 
    --and ((@Partners is null) or (p.Name = @Partners)) 
    and ((@Partners is null) or (p.Name in (select * from dbo.fnSplitString(@Partners, ',')))) 
    and ((@PriceFrom is null) or (dd.SalePrice >= @PriceFrom)) 
    and ((@PriceTo is null) or (dd.SalePrice <= @PriceTo)) 
    and ((@VATFrom is null) or (dd.VAT >= @VATFrom)) 
    and ((@VATTo is null) or (dd.VAT <= @VATTo)) 

    ) 

    Select * from ResultSet rs WHERE RowNumber between @StartPage and @EndPage 

    ORDER BY rs.Date ASC 

END

但後來我發現，我不得不做出一個過濾器不止一個「合作伙伴」（例如：合作伙伴1，合作伙伴2，...）。然後我寫了一個函數，它將SP參數@Partners分割成不同的字符串。但是當我在「where」子句中註釋了舊部分並提出新部分（調用函數wtrote）時，它給了我這個錯誤消息：「無法解決」Cyrillic_General_CI_AS「和」Cyrillic_General_CS_AS「之間的排序衝突等於操作「。當我試圖執行SP。並且錯誤在第26行，即： SET @StPagePage =（（@PageNumber-1）* @PageSize）+ 1; 我沒有改變任何東西。我讀了一些我在這裏發現的關於整理的matirials，但我仍然無法爲自己找出問題。我寫的功能是：

ALTER FUNCTION [dbo].[fnSplitString] 
( 
    @string NVARCHAR(MAX), 
    @delimiter CHAR(1) 
) 
RETURNS @output TABLE(splitdata NVARCHAR(200) 
) 
BEGIN 
    DECLARE @start INT, @end INT 
    SELECT @start = 1, @end = CHARINDEX(@delimiter, @string) 
    WHILE @start < LEN(@string) + 1 BEGIN 
     IF @end = 0 
      SET @end = LEN(@string) + 1 

     INSERT INTO @output (splitdata) 
     VALUES(SUBSTRING(@string, @start, @end - @start)) 
     SET @start = @end + 1 
     SET @end = CHARINDEX(@delimiter, @string, @start) 

    END 
    RETURN 
END

任何幫助將不勝感激。

來源

2016-10-14 ppetyr

你可以發表你的最新嘗試SP –

我貼吧，與最初SP的唯一的區別是評論的部分在WHERE子句中。 – ppetyr

您必須在比較IN語句前的結果OR之前設置默認排序規則。

試試你的WHERE條件如下：

and ((@Partners is null) or (p.Name COLLATE DATABASE_DEFAULT in (select * from dbo.fnSplitString(@Partners, ','))))

Set datatype to NVARCHAR of related column

來源

2016-10-14 06:10:13

我會嘗試你的第一個建議，但我必須等到我有權查看什麼是數據庫默認排序規則，因爲我現在不能。這可能需要一個小時或更多，如果有幫助，我會寫信給你。 – ppetyr

感謝您的幫助，我嘗試了您的第一個建議，我的SP成功執行 – ppetyr

SQL Server 2008存儲過程執行問題

回答

相關問題