MS Access VBA檢查Word是否已關閉？

Question

我有一個項目，需要我在Word中打開文檔並等待文檔打開。用戶然後需要編輯文檔，打印或保存文檔，然後手動關閉文檔。當文檔（或Word本身）關閉時，我想在Access中繼續使用我的VBA腳本。

我有以下代碼

If Len(Dir(sDocName)) > 0 Then 
    Dim wordApp As Word.Application 
    Dim wordDoc As Word.Document 

    ' Launch Word 
    Set wordApp = New Word.Application 

    ' Open the document 
    With wordApp 
     Set wordDoc = .Documents.Open(sDocName, , False) 

     ' Pass data 
     With wordDoc 
      .Variables("bmArchitectCompanyName").Value = "Hello" 
      .Variables("bmArchitectCompanyAddress").Value = "Hello" 
      .Variables("bmArchitectCompanyPostCode").Value = "Hello" 
      .Variables("bmArchitectContactFirstName").Value = "Hello" 
      .Variables("bmProjectTitle").Value = ProjectTitle 
      .Fields.Update 
     End With 
     .Visible = True 
     .Activate 

     Do Until wordApp Is Nothing 
      ' Wait for Word to be closed 
     Loop 

     ' Display a success message 
     MsgBox "Success!" 
    End With 
End If 

然而，做循環永遠不會退出。

如何檢查通過VBA啓動的文檔是否已由用戶從我的VBA代碼中關閉？

Answer 1

您必須使用DoEvents屈服於操作系統，然後檢查文檔是否關閉，否則coninue DoEvents循環。以下是我不幸測試不到的大綱代碼。

Do 
     DoEvents 
     For i = 1 to wordApp.Documents.Count 
      If (wordApp.Documents(i).Name = sDocName) Then Exit For 
     Next i 
     If (i > wordApp.Documents.Count) Then Exit Loop 
    Loop While (True) 

注意：您可能不想關閉應用程序，因爲用戶可能打開了其他文檔。也許你應該測試一下。

Answer 2

我已經找到了解決辦法...

Do While .Visible 
     ' wait until the window is no longer visible  
Loop 

不正是我一直在尋找，等待，直到字被關閉，然後用MS訪問VBA腳本繼續。

Answer 3

基於Paul輸入的內容，使用不同的方法來測試文檔是否打開。

Sub Test() 

    Dim wordApp As Word.Application 
    Dim wordDoc As Word.Document 
    Dim sDocName As String 

    sDocName = "<Full path to document>" 

    Set wordApp = New Word.Application 

    With wordApp 
     Set wordDoc = .Documents.Open(sDocName, , False) 
     .Visible = True 
     .Activate 

     Do 
      DoEvents 
     Loop While FileIsOpen(sDocName) 

    End With 

    MsgBox "Finished" 

End Sub 

Public Function FileIsOpen(FullFilePath As String) As Boolean 

    Dim ff As Long 

    On Error Resume Next 

    ff = FreeFile() 
    Open FullFilePath For Input Lock Read As #ff 
    Close ff 
    FileIsOpen = (Err.Number <> 0) 

    On Error GoTo 0 

End Function 

Answer 4

與檢查，看看是否wordApp Is Nothing是VBA不知道取消引用對象時其外部關閉了該問題。換句話說，當wordApp引用的文檔關閉時，指向該對象的指針變成虛假但不是Nothing。要捕獲的事件，您可以在出現錯誤做在環路的文檔對象的無意義的通話，並退出：

On Error Resume Next 
With wordDoc 
    Do 
    DoEvents 
    'This will only occur if there is an error: 
    If .Visible<>.Visible Then Exit Do 
    Loop 
End With 
Err.Clear 
On Error Goto 0 

Answer 5

我只是沒有迴路或其他任何測試。 Access中的宏代碼等待，直到Word應用程序的實例在完成執行之前關閉。下面是我測試過，並MSGBOX後，才退出Word執行：要確保將對象設爲Nothing或 你很有可能在未來的時間遇到​​錯誤信息

' Open the document 
With wordApp 
    Set wordDoc = .Documents.Add 

    ' Pass data 
    With wordDoc 
     .Variables("bmArchitectCompanyName").Value = "Hello" 
     .Variables("bmArchitectCompanyAddress").Value = "Hello" 
     .Variables("bmArchitectCompanyPostCode").Value = "Hello" 
     .Variables("bmArchitectContactFirstName").Value = "Hello" 
     .Content.Text = "test" 
     '.Variables("bmProjectTitle").Value = ProjectTitle 
     '.Fields.Update 
    End With 
    .Visible = True 
    .Activate 

    ' Display a success message 
    MsgBox "Success!" 
    Set wordDoc = Nothing 
    Set wordApp = Nothing 
End With 

注你運行代碼 ，因爲它會讓WinWord的實例在內存中打開。

Answer 6

如果您在類模塊或窗體模塊處理Word文檔，請嘗試聲明一個Word.Document對象是這樣的：

Dim WithEvents w As Word.Document 

，那麼你可以使用Word.Document對象事件「關閉「：

Private Sub w_Close() 

    'Things you want to do when the Word.Document is closed 

    'reset object 
    set w=nothing 

End Sub 

您不能讓」容器「窗體關閉或者對象終止，除非w不爲空。表單或對象是安靜的（或任何你想要他們做的），直到你的Word文檔被關閉。