重寫父程序具有相同名稱

Question

我想了解繼承了Fortran中是如何工作的，但有下面的代碼困難（對不起，如果這是一個常見問題...）：

module mymod 
    implicit none 

    type Pos 
     integer :: n_ = -1 
    contains 
     procedure :: set => Pos_set 
    endtype 

    type, extends(Pos) :: Vec 
     integer :: x_ = -2 
    contains 
     procedure :: set => Vec_set   !! (1) 
     !! procedure :: set => Vec_set_p !! (2) 
    endtype 

contains 

    subroutine Pos_set(p, n) 
     class(Pos) p 
     integer n 
     p% n_ = n 
    endsubroutine 

    subroutine Vec_set(v, n) 
     class(Vec) v 
     integer n 
     v% n_ = n 
     v% x_ = n * 10 
    endsubroutine 

    subroutine Vec_set_p(p, n) 
     class(Vec) p 
     integer n 
     p% n_ = n 
     p% x_ = n * 10 
    endsubroutine 

end 

program main 
    use mymod 
    implicit none 
    type(Pos) p 
    type(Vec) v 

    call p% set(10) 
    call v% set(20) 

    print *, "p = ", p 
    print *, "v = ", v 
end 

通過以上代碼，gfortran 5.2.1提供了以下錯誤消息：

procedure :: set => Vec_set 
     1 
Error: Dummy argument ‘v’ of ‘set’ at (1) should be named ‘p’ 
as to match the corresponding argument of the overridden procedure 

如果更改的set 到（即，由2替換第1行）的結合，其僅通過第一虛設的名稱是從Vec_set不同爭論，然後程序編譯得很好，並給出了預期的結果。我也收到了ifort-14.0和Oracle Fortran的類似錯誤。

這是否意味着要重寫父類型的過程，我們還需要照顧虛擬參數的名稱嗎？ （即，不僅是關於哪個類別的信息，還有變量的名稱？）

Answer 1

這不是一個有良好動機的答案，但是：是的，你需要關心假人的姓名參數。

4.5.7.3中的特定限制（在Fortran 2008中）。正如您已經指出的那樣，您在此處所取代的是類型爲vec的pos類型的綁定名稱set。如果擴展類型中的類型綁定過程與父類型中的可訪問類型綁定過程具有相同的綁定名稱，則會發生重寫。

對於壓倒性條件允許，在該部分給出了許多條件。值得注意的是以下兩種：

• 通過對象的虛擬參數，如果有的話，應通過名稱和位置相應。
• 按位置對應的虛擬參數應具有相同的名稱和特徵，但傳遞對象虛擬參數的類型除外。

如果在類型綁定過程中沒有pass屬性，則傳遞對象的僞參數是參數列表中的第一個參數。當你的編譯器抱怨時，覆蓋過程已經通過了 - 對象名稱的不同。

這個問題的例子沒有使用多態，所以在某種程度上這裏不需要關心重寫（這個過程可能有不同的綁定名稱）。

對於需要此動態分辨率的多態工作，請確保滿足上述限制條件。正如jlokimlin對傳遞的虛擬參數使用一個相當通用的名稱所評論的那樣，如this或self這很流行，這是在除了奇怪的情況下處理這個問題的簡單方法。

或者，關於重寫的一個關鍵部分是父類型綁定過程是可訪問的。如果兩個派生類型在不同的模塊中聲明並且父類型的綁定過程是私有的，那麼不會發生重寫，並且這些限制不適用。 [當然，父母的綁定名稱只能在其定義模塊中使用，但在許多情況下這可能已足夠。]