如何在鼠標仍然關閉的情況下檢測用戶窗體上的mouse_down

Question

當鼠標仍然關閉時，我想要檢測窗體上任何Frame上的mouse_down。我知道如何做點擊，但我想在mouse_up之前捕捉它。

感謝

Answer 1

您可以創建一個_MouseDown事件處理表單上的每個幀，或者如果你有很多框架，你可以創建一個通用的事件處理程序類

創建一個類模塊（例如命名爲cUserFormEvents）

Public WithEvents Frme As MSForms.frame 
Public frm As UserForm 

Private Sub Frme_MouseDown(_ 
ByVal Button As Integer, _ 
ByVal Shift As Integer, _ 
ByVal X As Single, _ 
ByVal Y As Single) 

    ' Put your event code here 
    MsgBox Frme.Caption 

End Sub 

聲明收集您的框架

Dim mcolFrames As New Collection 

包括此代碼在您的形式initialistion

Private Sub UserForm_Initialize() 
    Dim ctl As MSForms.Control 
    Dim clsEvents As cUserFormEvents 

    'Loop through all controls on userform 
    For Each ctl In Me.Controls 
     'Only process Frames 
     If TypeOf ctl Is MSForms.frame Then 
      'Instantiate class module and assign properties 
      Set clsEvents = New cUserFormEvents 
      Set clsEvents.Frme = ctl 
      Set clsEvents.frm = Me 

      'Add instance to collection 
      mcolFrames.Add clsEvents 

     End If 

    Next ctl 

End Sub 

現在，Frme_MouseDown將執行上的MouseDown在窗體上的任何框架。使用Frme