從祖先的祖先繼承方法

Question

我正在研究從商業組件套件派生的組件，並且遇到了一個我從未考慮過的挑戰。請看下面的代碼片段：

TMyClass = class 
protected 
    procedure SomeMethod; virtual; 
end; 

TMyClass1 = class(TMyClass) 
protected 
    procedure SomeMethod; override; 
end; 

TMyMode = (mmOne, mmTwo); 
TMyClass2 = class(TMyClass1) 
private 
    FMode: TMyMode; 
protected 
    procedure SomeMethod; override; 
public 
    property Mode: TMyMode read FMode write FMode; 
end; 

... 

procedure TMyClass2.SomeMethod; 
begin 
    if FMode = mmOne then inherited SomeMethod 
        else inherited TMyClass.SomeMethod; 
end; 

所以，如果模式= mmOne然後我繼承是正常的，但如果它是mmTwo，我還是想繼承我的祖先的祖先的代碼，但是不知道是在祖先介紹。我已經嘗試了上述，但沒有成功，因爲我以前從未遇到過這種情況，所以我認爲這是不可能的。任何接受者？

Answer 1

你可以用類傭工這樣做：

type 
    TA = class 
    public 
    procedure X; virtual; 
    end; 

    TB = class(TA) 
    public 
    procedure X; override; 
    end; 

    TA_Helper = class helper for TA 
    procedure A_X; 
    end; 

    TC = class(TB) 
    public 
    procedure X; override; 
    end; 

procedure TA.X; 
begin 
    // ... 
end; 

procedure TB.X; 
begin 
    // ... 
end; 

procedure TA_Helper.A_X; 
begin 
    inherited X; // TA.X 
end; 

procedure TC.X; 
begin 
    A_X; 
    inherited X; // TB.X 
end; 

我覺得在D2006中存在類的幫手，但如果他們不這樣做，你也可以使用一劈到一樣的效果：

// ... 
    TA_Helper = class(TA) 
    procedure A_X; 
    end; 
// ... 
procedure TC.X; 
begin 
    TA_Helper(Self).A_X; 
    inherited X; // TB.X 
end; 

Answer 2

有沒有類助手或其他方法（如在@ hvd答案）這個任務的另一種解決方案。你可以得到基類方法的代碼地址和self數據指針調用它：
更新的代碼，沒有RTTI

unit Unit4; 

interface 
type 
    TA = class(TObject) 
     protected 
     procedure Test(); virtual; 
    end; 

    TB = class(TA) 
     protected 
     procedure Test(); override; 
    end; 

    TC = class(TB) 
     public 
     procedure Test(); override; 
    end; 

implementation 

procedure TA.Test; 
begin 
    writeln('TA.Test()'); 
end; 

procedure TB.Test; 
begin 
    writeln('TB.Test'); 
end; 

procedure TC.Test; 
var TATest : procedure of object; 
begin 
    writeln('TC.Test();'); 
    writeln('call inherited TB: '); 
    inherited Test(); 


    writeln('call inherited TA:'); 
    TMethod(TATest).Data := self; 
    TMethod(TATest).Code := @TA.Test; 
    TATest(); 
end; 
end.