的Clojure - 變換嵌套地圖

Question

我想創建嵌套地圖mermaid圖這樣

{"a" {"b" {"c" nil 
      "d" nil}} 
"e" {"c" nil 
     "d" {"h" {"i" nil 
       "j" nil}}}} 

我覺得應該先轉換嵌套的地圖這種形式。那麼它應該很容易。

[{:out-path "a" :out-name "a" 
    :in-path "a-b" :in-name "b"} 
{:out-path "a-b" :out-name "b" 
    :in-path "a-b-c" :in-name "c"} 
{:out-path "a-b" :out-name "b" 
    :in-path "a-b-d" :in-name "d"} 
{:out-path "e" :out-name "e" 
    :in-path "e-f" :in-name "f"} 
{:out-path "e" :out-name "e" 
    :in-path "e-c" :in-name "c"} 
{:out-path "e" :out-name "e" 
    :in-path "e-d" :in-name "d"} 
{:out-path "e-d" :out-name "d" 
    :in-path "e-d-h" :in-name "h"} 
{:out-path "e-d-h" :out-name "h" 
    :in-path "e-d-h-i" :in-name "i"} 
{:out-path "e-d-h" :out-name "h" 
    :in-path "e-d-h-j" :in-name "j"}] 

編輯：

這是我創造。但我完全不知道如何添加結果地圖的路徑。

(defn myfunc [m] 
    (loop [in m out []] 
    (let [[[k v] & ts] (seq in)] 
     (if (keyword? k) 
     (cond 
      (map? v) 
      (recur (concat v ts) 
       (reduce (fn [o k2] 
          (conj o {:out-name (name k) 
            :in-name (name k2)})) 
         out (keys v))) 
      (nil? v) 
      (recur (concat v ts) out)) 
     out)))) 

Answer 1

據我可以通過人魚文檔看到，繪製圖表它足以產生的「X - > Y」的形式的所有節點對。

，我們可以做到這一點與一些簡單的遞歸函數（我相信，有沒有在圖表中這麼多層次擔心堆棧溢出）：

(defn map->mermaid [items-map] 
    (if (seq items-map) 
    (mapcat (fn [[k v]] (concat 
          (map (partial str k "-->") (keys v)) 
          (map->mermaid v))) 
     items-map))) 

在REPL：

user> 
(map->mermaid {"a" {"b" {"c" nil 
         "d" nil}} 
       "e" {"c" nil 
        "d" {"h" {"i" nil 
           "j" nil}}}}) 

;; ("a-->b" "b-->c" "b-->d" "e-->c" "e-->d" "d-->h" "h-->i" "h-->j") 

所以現在你只需要做一個這樣的圖表：

(defn create-graph [items-map] 
    (str "graph LR" 
     \newline 
     (clojure.string/join \newline (map->mermaid items-map)) 
     \newline)) 

更新

你可以使用同樣的策略在實際地圖變形，​​剛好路過電流路徑map->mermaid：

在REPL

(defn make-result-node [path name child-name] 
    {:out-path path 
    :out-name name 
    :in-path (str path "-" child-name) 
    :in-name child-name}) 

(defn map->mermaid 
    ([items-map] (map->mermaid "" items-map)) 
    ([path items-map] 
    (if (seq items-map) 
    (mapcat (fn [[k v]] 
       (let [new-path (if (seq path) (str path "-" k) k)] 
       (concat (map (partial make-result-node new-path k) 
           (keys v)) 
         (map->mermaid new-path v)))) 
      items-map)))) 

：

user> 
(map->mermaid {"a" {"b" {"c" nil 
         "d" nil}} 
       "e" {"c" nil 
        "d" {"h" {"i" nil 
           "j" nil}}}}) 

;; ({:out-path "a", :out-name "a", :in-path "a-b", :in-name "b"} 
;; {:out-path "a-b", :out-name "b", :in-path "a-b-c", :in-name "c"} 
;; {:out-path "a-b", :out-name "b", :in-path "a-b-d", :in-name "d"} 
;; {:out-path "e", :out-name "e", :in-path "e-c", :in-name "c"} 
;; {:out-path "e", :out-name "e", :in-path "e-d", :in-name "d"} 
;; {:out-path "e-d", :out-name "d", :in-path "e-d-h", :in-name "h"} 
;; {:out-path "e-d-h", :out-name "h", :in-path "e-d-h-i", :in-name "i"} 
;; {:out-path "e-d-h", :out-name "h", :in-path "e-d-h-j", :in-name "j"})