創建一個安裝程序，將執行更新，如果已經安裝了舊版本

Question

我想爲我的軟件（這是一個C＃軟件）配置Inno安裝程序。 我打算髮布我的軟件的很多版本，如果我的應用程序的舊版本已經安裝在計算機上，我想更改inno setup安裝程序界面。 在這種情況下，用戶不應該能夠更改安裝目錄。

有四種情況：

第一種情況：這是我的產品的第一次安裝，Inno Setup的程序正常進行。

第二種情況：該產品已經安裝完畢且安裝程序包含更新的版本。用戶不能選擇目標文件夾。他可以運行更新。

第三種情況：如果安裝程序包含的版本比安裝的版本舊，則更新將被禁用，並且應顯示消息。

第四種情況：安裝程序版本與安裝版本相同。如果需要，用戶可以修復他的執行版本。

InnoSetup可以做到嗎？

Answer 1

如果您的AppID在應用程序的生命週期中保持不變，Inno Setup會自動處理案例1,2和4。
您還可以使用以下[Setup]指令隱藏的目錄和組頁：

DisableDirPage=auto 
DisableGroupPage=auto 

有關詳細信息，請參閱本ISXKB article。對於案例3，假設您的文件版本正確，Inno不會降級任何內容，但它實際上不會對用戶發出警告。要做到這一點，您需要添加代碼來檢查這一點，很可能在InitializeSetup()事件函數中。

Answer 2

如果你想對用戶有一些反饋，你可以嘗試類似的東西。 首先，您的更新應該與您的主應用程序具有相同的AppId名稱。 然後您可以設置一些檢查，即顯示消息以通知用戶有關狀態。

#define MyAppVersion "1.2.2.7570" 
#define MyAppName "MyApp Update" 

[Setup] 
AppId=MyApp 
AppName={#MyAppName} 
AppVersion={#MyAppVersion} 
DefaultDirName={reg:HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\MyApp_is1,InstallLocation} 
DisableDirPage=True 

[CustomMessages] 
MyAppOld=The Setup detected application version 
MyAppRequired=The installation of {#MyAppName} requires MyApp to be installed.%nInstall MyApp before installing this update.%n%n 
MyAppTerminated=The setup of update will be terminated. 

[Code] 
var 
InstallLocation: String; 

function GetInstallString(): String; 
var 
InstPath: String; 
InstallString: String; 
begin 
InstPath := ExpandConstant('Software\Microsoft\Windows\CurrentVersion\Uninstall\MyApp_is1'); 
InstallString := ''; 
if not RegQueryStringValue(HKLM, InstPath, 'InstallLocation', InstallString) then 
RegQueryStringValue(HKCU, InstPath, 'InstallLocation', InstallString); 
Result := InstallString; 
InstallLocation := InstallString; 
end; 

function InitializeSetup: Boolean; 
var 
V: Integer; 
sUnInstallString: String; 
Version: String; 
begin 
    if RegValueExists(HKEY_LOCAL_MACHINE,'Software\Microsoft\Windows\CurrentVersion\Uninstall\MyApp_is1', 'UninstallString') then begin 
     RegQueryStringValue(HKEY_LOCAL_MACHINE,'Software\Microsoft\Windows\CurrentVersion\Uninstall\MyApp_is1', 'DisplayVersion', Version); 
     if Version =< ExpandConstant('{#MyAppVersion}') then begin 
      Result := True; 
      GetInstallString(); 
     end 
     else begin 
MsgBox(ExpandConstant('{cm:MyAppOld}'+Version+'.'+#13#10#13#10+'{cm:MyAppRequired}'+'{cm:MyAppTerminated}'), mbInformation, MB_OK); 
     Result := False; 
    end; 
end 
else begin 
    MsgBox(ExpandConstant('{cm:MyAppRequired}'+'{cm:MyAppTerminated}'), mbInformation, MB_OK); 
    Result := False; 
end; 
end;