更改VBA宏代碼更改

Question

數

我試圖做的是增量數，然後通過循環1 減去第一2數字，然後遞增休息，直到第一2位數= 0

所以我有M201001將成爲m191002和明年將是m181003直到m011020

Answer 1

什麼你需要做的是你的價值分手使用left，mid和right功能3成。

然後根據需要進行循環。我自己嘗試一下，所以一旦我這樣做，我會更新我的答案。

添加的代碼：

Sub Testing() 

    Dim myIn As String 
    myIn = "M201001" 

    Dim myLeft As String 
    Dim myMid As Integer, myRight As Integer, i As Integer 
    Dim myOut As String 
    myLeft = Left(myIn, 1) 
    myMid = CInt(Mid(myIn, 2, 2)) 
    myRight = CInt(Right(myIn, 4)) 
    myOut = myLeft & Format(myMid, "00") & Format(myRight, "0000") 
    i = 0 

    Debug.Print "IN:  " & myIn 
    Debug.Print "BROKEN UP: " & myOut 

    Do Until myMid = -1 
     Debug.Print "ITERATION " & Format(i, "00") & ": " & myLeft & Format(myMid, "00") & Format(myRight, "0000") 

     myMid = myMid - 1 
     myRight = myRight + 1 
     myOut = myLeft & Format(myMid, "00") & Format(myRight, "0000") 
     i = i + 1 
    Loop 

End Sub 

如果您需要任何解釋，請詢問。我會很樂意解釋。

Answer 2

使用試試這個

Function GetNextNumber(n As String) As Variant 
    ' Validate input 
    If Len(n) <> 7 Then 
     GetNextNumber = xlErrNum 
     Exit Function 
    ElseIf Left$(n, 1) <> "M" Then 
     GetNextNumber = CVErr(xlErrNum) 
     Exit Function 
    End If 

    GetNextNumber = Left$(n, 1) & Format(val(Mid$(n, 2)) - 9999, "000000") 

End Function 

測試此

Sub demo() 
    Dim n As Variant 

    n = "M201001" 
    Debug.Print n 
    Do 
     n = GetNextNumber(CStr(n)) 
     If IsError(n) Then Exit Sub 
     Debug.Print n 
    Loop Until val(Mid$(n, 2)) <= 19999 
End Sub