在clojure中的應用程序和庫之間的依賴注入

Question

我將我的應用程序的一部分分成庫

庫函數具有必須由應用程序注入的某些依賴項。我有一個協議爲藍本這個

(defprotocol MyLibDependencies 
    (some-injected-capability [x])) 

(defrecord Foo [y]) 
(defrecord Bar [y]) 

(defmulti render-response class) 

(defmethod render-response Foo [val] {:ok (some-injected-capability (:y val))}) 
(defmethod render-response Bar [val] {:err (some-injected-capability (:y val))}) 

，並在這裏的應用程序，我可以提供一個實現：

(extend-type Object 
    MyLibDependencies 
    (some-injected-capability [x] (inc x))) 

(comment 
    (render-response (Foo. 10)) ;; => {:ok 11} 
    (render-response (Bar. 10)) ;; => {:err 11} 
) 

這工作，但感覺就像協議的濫用，因爲我既不需要多態分派，注入的函數也不一定需要參數（協議需要至少一個參數來調度它的類）。我有什麼選擇？

請注意，Foo和Bar記錄是庫域類型，而render-response方法也是庫域。我不一定在意如何定義它們，但它們所代表的抽象是圖書館領域。

Answer 1

這是一個有點接近，你會怎麼通常看到用於向圖書館提供了從客戶端代碼的功能協議：

;; lib.clj 
(defprotocol MyLibDependencies 
    (provide-status [this x]) 
    (provide-response [this x])) 

(defn render-response 
    [responder val] 
    {:status (provide-status responder val) 
    :code (provide-response responder val)}) 

;; client.clj 
(defrecord Foo [y] 
    MyLibDependencies 
    (provide-status [this val] 
    (if (even? val) 
     :ok 
     :err)) 
    (provide-response [this val] 
    (+ y val))) 

(defrecord Bar [y] 
    MyLibDependencies 
    (provide-status [this val] 
    (if (odd? val) 
     :ok 
     :err)) 
    (provide-response [this val] 
    (+ y val))) 


(comment 
    (render-response (Bar. 10) 1) ;; => {:status :ok :code 11} 
    (render-response (Foo. 10) 1) ;; => {:status :err :code 11} 
) 

有這種風格在野外的Clojure代碼的例子不勝枚舉 - 事實上構成Clojure本身的大多數核心功能最終都會解析爲調用由正在使用的特定數據結構提供的協議方法，或者針對單個數據類型擴展多方法調用。