如何比較vb.net中的字節數組

Question

好吧，我想要做的就是比較vb.net中的2個字節數組。我試圖這些代碼：

If Byte.ReferenceEquals(bytearrayone, bytearraytwo) Then 
    MsgBox("Yes", MsgBoxStyle.Information) 
Else 
    MsgBox("No", MsgBoxStyle.Critical) 
End If 

而且

If Array.ReferenceEquals(bytearrayone, bytearraytwo) Then 
    MsgBox("Yes", MsgBoxStyle.Information) 
Else 
    MsgBox("No", MsgBoxStyle.Critical) 
End If 

兩個字節陣列是相同的，一個陣列從一個資源文件，並從計算機上的其他以字節。出於測試目的，我在兩個數組中使用了相同的文件，但根據所提供的代碼，我得到的都是No。兩者都有相同的長度，我穿過他們兩個，都有相同的字節相同的點。那麼怎麼了？我應該使用哪些代碼？請幫幫我。

Answer 1

使用SequenceEqual

Dim foo() As Byte = {1, 2, 3, 4} 
    Dim barT() As Byte = {1, 2, 3, 4} 
    Dim barF() As Byte = {1, 2, 3, 5} 

    Dim fooEqbarT As Boolean = foo.SequenceEqual(barT) 
    Dim fooEqbarF As Boolean = foo.SequenceEqual(barF) 

    Debug.WriteLine(fooEqbarT) 
    Debug.WriteLine(fooEqbarF) 

比較兩個小文件

Dim path1 As String = "pathnameoffirstfile" 
    Dim path2 As String = "pathnameofsecondfile" 

    Dim foo() As Byte = IO.File.ReadAllBytes(path1) 
    Dim bar() As Byte = IO.File.ReadAllBytes(path2) 

    If foo.SequenceEqual(bar) Then 
     'identical 
    Else 
     'different 
    End If 

Answer 2

如果你的目的是比較2個文件，看是否內容是相同的，沒有關於該文件的問候信息（即修改日期，名稱，類型等），您應該對這兩個文件使用散列。這是我用了一段時間的一些代碼。有很多方法可以做到這一點。

''' <summary> 
''' Method to get a unique string to idenify the contents of a file. 
''' Works on any type of file but may be slow on files 1 GB or more and large files across the network. 
''' </summary> 
''' <param name="FI">System.IO.FileInfo for the file you want to process</param> 
''' <returns>String around 50 characters long (exact length varies)</returns> 
''' <remarks>A change in even 1 byte of the file will cause the string to vary 
''' drastically so you cannot use this to see how much it differs by.</remarks> 
Public Shared Function GetContentHash(ByVal FI As System.IO.FileInfo) As String 
    Dim SHA As New System.Security.Cryptography.SHA512Managed() 
    Dim sBuilder As System.Text.StringBuilder 
    Dim data As Byte() 
    Dim i As Integer 
    Using fs As New IO.FileStream(FI.FullName, IO.FileMode.Open) 
     data = SHA.ComputeHash(fs) 
     fs.Flush() 
     fs.Close() 
    End Using 
    sBuilder = New System.Text.StringBuilder 
    ' Loop through each byte of the hashed data 
    ' and format each one as a hexadecimal string. 
    For i = 0 To data.Length - 1 
     sBuilder.Append(data(i).ToString("x2")) 
    Next i 
    Return sBuilder.ToString() 
End Function 

您需要在每個文件上運行該命令，以獲得唯一標識文件的字符串，然後比較2個字符串。