是否有可能從異常繼續循環？

Question

我有一個循環內執行的提取。如果此提取失敗（無數據），我想CONTINUE循環到EXCEPTION內的下一條記錄。

這可能嗎？

我得到一個ORA-06550 & PLS-00201 identifer CONTINUE must be declared

DECLARE 
    v_attr char(88); 
CURSOR SELECT_USERS IS 
SELECT id FROM USER_TABLE 
WHERE USERTYPE = 'X'; 
BEGIN 
    FOR user_rec IN SELECT_USERS LOOP  
     BEGIN 
      SELECT attr INTO v_attr 
      FROM ATTRIBUTE_TABLE 
      WHERE user_id = user_rec.id;    
     EXCEPTION 
      WHEN NO_DATA_FOUND THEN 
       -- user does not have attribute, continue loop to next record. 
       CONTINUE; 
     END;   
    END LOOP; 
END; 

Answer 1

的CONTINUE聲明是在11g中的新功能。

這裏有一個相關的問題：'CONTINUE' keyword in Oracle 10g PL/SQL

Answer 2

在您所提供的結構，你不需要繼續。處理異常後，執行END後的語句，假定您的EXCEPTION塊不會終止該過程。換句話說，它將繼續進行user_rec循環的下一次迭代。

你還需要選擇到一個變量的BEGIN塊中：

SELECT attr INTO v_attr FROM attribute_table... 

顯然，你必須聲明v_attr以及...

Answer 3

如何在OLE goto語句（我知道，我知道，但它工作得很好這裏;）

DECLARE 
    v_attr char(88); 
CURSOR SELECT_USERS IS 
SELECT id FROM USER_TABLE 
WHERE USERTYPE = 'X'; 
BEGIN 
    FOR user_rec IN SELECT_USERS LOOP  
     BEGIN 
      SELECT attr INTO v_attr 
      FROM ATTRIBUTE_TABLE 
      WHERE user_id = user_rec.id;    
     EXCEPTION 
      WHEN NO_DATA_FOUND THEN 
       -- user does not have attribute, continue loop to next record. 
       goto end_loop; 
     END; 

     <<end_loop>> 
     null;   
    END LOOP; 
END; 

只要把end_loop在最末端當然循環。 null可以用一個提交或者一個計數器增量代替，直到你。

Answer 4

在這個例子中，你真的應該只使用一個外連接。

declare 
begin 
    FOR attr_rec IN ( 
    select attr 
    from USER_TABLE u 
    left outer join attribute_table a 
    on (u.USERTYPE = 'X' and a.user_id = u.id) 
) LOOP 
    <process records> 
    <if primary key of attribute_table is null 
    then the attribute does not exist for this user.> 
    END LOOP; 
END; 

Answer 5

通知您可以使用WHEN exception THEN NULL相同的方式，你會使用WHEN exception THEN continue。示例：

DECLARE 
     extension_already_exists EXCEPTION; 
     PRAGMA EXCEPTION_INIT(extension_already_exists, -20007); 
     l_hidden_col_name varchar2(32); 
    BEGIN 
     FOR t IN ( SELECT table_name, cast(extension as varchar2(200)) ext 
        FROM all_stat_extensions 
        WHERE owner='{{ prev_schema }}' 
         and droppable='YES' 
        ORDER BY 1 
       ) 
     LOOP 
      BEGIN 
       l_hidden_col_name := dbms_stats.create_extended_stats('{{ schema }}', t.table_name, t.ext); 
      EXCEPTION 
       WHEN extension_already_exists THEN NULL; -- ignore exception and go to next loop iteration 
      END; 
     END LOOP; 
    END;