比較for循環中數字的絕對值以確定它是否被使用？

，現在我明白我在這篇文章中提到的更大的問題... Searching a text file and sending only numbers greater than a certain absolute value to text file?比較for循環中數字的絕對值以確定它是否被使用？

我想如果我set num=!num:-=!用的，比方說，-17原始值，那麼!errorlevel!將評估結果爲true或0吧？有些東西在這裏雖然不起作用，但...

爲了澄清，我只需要篩選出第四個標記大於3或小於-3的第一個和第四個標記，以及任何行沒有第四個標記（這部分已解決）。我已經嘗試使用集合的/A選項，它似乎仍然工作。

setlocal enabledelayedexpansion 

set "min=-" 

for /f "tokens=1,4" %%a in ('findstr /b /r /c:"[^ ]*:S:" print.log') do (
    if %%b=="" (echo %%a ^*^*^* >>new.txt) else (
     set num="%%b" 
     set num=!num:-=! 
     if !errorlevel!==0 (
      if !num! GTR 3 echo %%a !min!!num! >> new.txt 
     ) else (
      if !num! GTR 3 echo %%a !num! >> new.txt 
     ) 
    ) 
) 

exit /b

在print.log的文字是這樣的：

ksdf 0 0 -4

as7d：S：ASF 0 0 -4

KC：S：CD3 0 0 - 2

asdk：S：s 0 0 6

la SD：S：DD 0 0

來源

2017-03-07 Glycoversi

@echo off 
    setlocal enableextensions disabledelayedexpansion 

    >"new.txt" (
     for /f "tokens=1,4" %%a in (' 
      findstr /b /r /c:"[^ ]*:S:" print.log 
     ') do if "%%~b"=="" (echo %%a ***) else (
      set "print=1" 
      if %%b lss 4 if %%b gtr -4 set "print=" 
      if defined print echo %%a %%b 
     ) 
    )

除了打印時的值小於-3或大於3時，當該值大於4小於-4

-6 -5 -4 -3 -2 -1 0 1 2 3 4 5 6 
      ^.................^ 
       don't print

來源

2017-03-07 07:42:23

我真的很喜歡這種方法。優雅！謝謝@ MC ND！ – Glycoversi

set /A num=%%b 
set num=!num:-=!

這建立num作爲%%b算術值。請注意，環境變量是總是字符串。分配按需要進行各種轉換。你的任務會分配一個值（例如）"-4"（包括引號）

第二個命令使用串在num和更改所有-到*nothing*因此計算absolte價值假設它是適當的-number結構。除此之外，我不知道你的意圖是創建你的輸出，因爲你;沒有指出輸出應該是什麼。無論如何，errorlevel將不會受到AFIIAA的set影響。

請注意，%%b仍將包含您使用echo處讀取的原始數字。您可以在%%b和!num!上執行if - 並根據需要在您的echo中使用%%b或!num!。

你不說什麼你gtr 3企業是專門做...

@ECHO OFF 
SETLOCAL ENABLEDELAYEDEXPANSION 
SET "sourcedir=U:\sourcedir" 
SET "filename1=%sourcedir%\q42639932.txt" 
FOR /f "tokens=1,4" %%a IN ('findstr /b /r /c:"[^ ]*:S:" "%filename1%"') DO (
if "%%b"=="" (echo %%a ^*^*^*) else (
    set num=%%b 
    set num=!num:-=! 
    if !num! GTR 3 (echo %%a %%b 
) else (
    ECHO just FOR demo %%a %%b 
) 
) 
) 

GOTO :EOF

你需要改變的sourcedir設置，以滿足您的具體情況。

我使用了一個名爲q42639932.txt的文件，其中包含您的數據+額外資料用於我的測試。

對於每個通過findstr濾波器，如果column4缺少線，產生星號否則在%%b設置num到的值，並從它除去任何-。如果結果數字大於3，則另外回顯原始%%b - 好吧，我已經完成了一條報告。顯然，這可以是rem med out。

來源

2017-03-07 04:15:42 Magoo

正如較低和更大的未打印一個學術練習，也可以通過[按位操作]獲取數字的絕對值（http://stackoverflow.com/a/12041874/1683264）。 'set/a「x = %%〜b，mask = x >> 31，x =（x^mask） - mask」' – rojo

@Magoo Ive更新了我的帖子以闡明我的目標。基本上我想從第四個標記中的值小於-3或大於3的所有行中獲取標記1和4併發送到文件。/a選項似乎不這樣做。 – Glycoversi

@ECHO OFF 
SETLOCAL EnableExtensions EnableDelayedExpansion 
set "threshold=3" 
>new.txt (
    for /f "tokens=1,4" %%a in ('findstr /b /r /c:"[^ ]*:S:" print.log') do (
     if "%%b"=="" (
      echo %%a ^*^*^* 
     ) else (
      set /A num=%%b 
      if !num! GEQ 0 (
       set "min=" 
      ) else (
       set "num=!num:-=!" 
       set "min=-" 
      ) 
      if !num! GTR %threshold% echo %%a !min!!num! 
     ) 
    ) 
)

來源

2017-03-07 07:48:56 JosefZ

比較for循環中數字的絕對值以確定它是否被使用？

回答

相關問題