選擇多個列表框項目來設置過濾器

Question

我想選擇一個年份和業務類型（1或更多），然後自動篩選一列。這樣，我只能使用1個宏而不是爲所有替代品製作多個宏。

(Year Select)
(Type of Business)

這是我的時刻：

Private Sub Botton1_Click() 
Public Platform As String 
Public Year as Integer 
Platform = UserForm1.LB2.Text 
Year = UserForm1.LB1.value 
Unload UserForm1 


End Sub 

......

Private Sub UserForm_Initialize() 
With LB1 

.AddItem "2016" 
.AddItem "2017" 
.AddItem "2018" 

End With 

With LB2 

.AddItem "CMP" 
.AddItem "AS" 
.AddItem "MasterBread" 
.AddItem "CMI -Andino" 
.AddItem "CMI -Brasil" 
.AddItem "CMI -CAMEC" 
.AddItem "CMI -ConoSur" 
.AddItem "Global" 
End With 

End Sub 

年將永遠是隻值1但商業類型可以是1或更多。

如何存儲多個列表框的值以便將該變量作爲過濾器調用？

這是我需要調用變量：

ActiveSheet.Range("$A$1:$G$1500").AutoFilter Field:=4, Criteria1:="2016" 
ActiveSheet.Range("$A$1:$G$1500").AutoFilter Field:=2, Criteria1:="=AS", _ 
    Operator:=xlOr, Criteria2:="=MASTER BREAD" 

在這個例子中，我需要過濾「2016」和「AS & MASTER麪包」。

Answer 1

註釋代碼，您的按鈕應該使用的基礎上，你已經在你的問題提供了什麼：

Private Sub Botton1_Click() 

    Dim rData As Range 
    Dim sFilters As String 
    Dim i As Long 

    Set rData = ActiveSheet.Range("$A$1:$G$1500") 
    rData.AutoFilter 'Remove any existing filters 

    'Get the selected year 
    If LB1.ListIndex > -1 Then 
     'Filter the year 
     rData.AutoFilter 4, LB1.Text 
    End If 

    'Gather all selected values in LB2 (type of business) 
    For i = 0 To LB2.ListCount - 1 
     'If value is selected, add to sFilters variable 
     If LB2.Selected(i) Then sFilters = sFilters & "|" & LB2.List(i) 
    Next i 

    If Len(sFilters) > 0 Then 
     'Filter on selected values 
     rData.AutoFilter 2, Split(sFilters, "|"), xlFilterValues 
    End If 

End Sub