需要使用VBA更改複製的Excel公式的名稱

Question

我在工作簿中有名爲Wk1，Wk2 Wk3等的工作表。

所有在WK1片的公式由WK1例如= Wk1MonWeight

前綴複製從WK1片式的任何我使用的代碼的另一片材的後下方的前綴WK1改變的名稱它們被複制到例如複製= Wk1MonWeight到Wk2表格後公式變爲= Wk2MonWeight。此代碼有效。

Sub Step2ChangeWkNamesInFormulasOnNewWksheet() 

    Dim ws As Worksheet 
    Dim r As Range 

    For Each ws In Worksheets 
     If InStr(1, ws.Name, "Wk", 1) > 0 Then 
      For Each r In ws.Range("C116:I119") 
       r.Formula = Replace(r.Formula, "Wk1", r.Parent.Name) 
      Next r 

      For Each r In ws.Range("C184:J188") 
       r.Formula = Replace(r.Formula, "Wk1", r.Parent.Name) 
      Next r 

      For Each r In ws.Range("E341:AY341") 
       r.Formula = Replace(r.Formula, "Wk1", r.Parent.Name) 
      Next r 


     End If 
    Next ws 

    MsgBox "Done" 
    End Sub 

我想改變片下面的代碼，以使從WK1到緊接在片材之前的片材的名稱前綴的變化被複制到+平均。 e.g當公式= Wk1MonWeight從WK1片與WK 4片複製變得= Wk3AvgWeight

For Each r In ws.Range("E341:AY341") 
       r.Formula = Replace(r.Formula, "Wk1", r.Parent.Name) 
      Next r 

任何人都可以與此幫助。

謝謝

Answer 1

根據你的描述，這應該這樣做：

編輯

Sub Step2ChangeWkNamesInFormulasOnNewWksheet() 
    Application.ScreenUpdating = False 
    Application.EnableEvents = False 
    On Error GoTo ErrHandler 

    Dim ws As Worksheet, r As Range 
    For Each ws In Worksheets 
     If InStr(1, ws.Name, "Wk", 1) = 1 And InStr(1, ws.Name, "Wk1", 1) = 0 Then 
      For Each r In ws.Range("C116:I119, C184:J188") 
       r.Formula = Replace(r.Formula, "Wk1", r.Parent.Name) 
      Next r 
      For Each r In ws.Range("E341:AY341") 
       r.Formula = Replace(r.Formula, "Wk1Mon", Sheets(r.Parent.Index - 1).Name & "Avg") 
      Next r 
     End If 
    Next 

    Application.ScreenUpdating = True 
    Application.EnableEvents = True 
    MsgBox "Done" 
    Exit Sub 

ErrHandler: 
    MsgBox "Something Went wrong: " & vbCrLf & Err.Description 
    Application.ScreenUpdating = True 
    Application.EnableEvents = True 
End Sub