Haskell：將偶數和奇數元素分解爲元組

Question

我不能使用高階函數。我看不出如何做到這一點。我對哈斯克爾很新。它也必須是遞歸的。

split :: [Int] -> ([Int],[Int]) 
split xs = 

我給了這個開始。我真的不知道從哪裏開始解決這個問題。

例子：

split [] 
([],[]) 

split [1] 
([1],[]) 

split [1,2,3,4,5,6,7,8,9,10] 
([1,3,5,7,9],[2,4,6,8,10]) 

任何幫助，將不勝感激。

編輯：它的偶數和奇數位置。

所以

分裂[3,6,8,9,10]將 （[3,8,10]，[6,9]）

行，所以我想出了這個。它不漂亮，但它似乎工作正常。

split :: [Int] -> ([Int],[Int]) 
split [] = ([],[]) 
split [xs] = ([xs],[]) 
split xs = (oddlist xs, evenlist xs) 

oddlist :: [Int] -> ([Int]) 
oddlist xs | length xs <= 2 = [head(xs)] 
      | otherwise = [head(xs)] ++ oddlist(tail(tail(xs))) 

evenlist :: [Int] -> ([Int]) 
evenlist xs | length xs <= 3 = [head(tail(xs))] 
      | otherwise = [head(tail(xs))] ++ evenlist(tail(tail(xs))) 

Answer 1

split [] = ([], []) 
split [x] = ([x], []) 
split (x:y:xs) = (x:xp, y:yp) where (xp, yp) = split xs 

Answer 2

如果你不能使用更高次序列表功能，您的選擇是基本上使用遞歸。

的例子已經給你需要迎合情況：

-- Base case: 
split [] = … 

-- Recurrence: 
split (x : xs) = (do something with x) … (split xs) … 

Answer 3

既然你已經把你的解決方案了，現在，這是我將如何實現它：

split xs = (everyother 0 xs, everyother 1 xs) 
     where everyother _ []  = [] 
      everyother 1 (x:xs) = everyother 0 xs 
      everyother 0 (x:xs) = x : (everyother 1 xs) 

這意味着列表中的第一項是項目0.

Answer 4

我認爲這與Get every Nth element有關。

無論如何，這是我會做什麼：

ghci> let split ys = let skip xs = case xs of { [] -> [] ; [x] -> [x] ; (x:_:xs') -> x : skip xs' } in (skip ys, skip . drop 1 $ ys) 
ghci> split [1..10] 
([1,3,5,7,9],[2,4,6,8,10]) 

還是很好的格式化的：

split xs = (skip xs, skip . drop 1 $ xs) 
    where 
    skip [] = [] 
    skip [x] = [x] 
    skip (x:_:xs') = x : skip xs' 

Answer 5

如果你放鬆了「沒有高階函數」的限制，你可以像下面這樣做：

split :: [a] -> ([a],[a]) 
split = foldr (\x ~(y2,y1) -> (x:y1, y2)) ([],[]) 

注意~使模式匹配懶惰，所以split可以根據需求產生結果，而不需要首先檢查整個列表。

您可以通過展開foldr重新實行限制：

split :: [a] -> ([a],[a]) 
split [] = ([],[]) 
split (x : xs) = (x : y1, y2) 
    where 
    (y2, y1) = split xs