VB.NET結合WPF

Question

我有這個在我的XAML文件：

<Button Click="Button_Click" 
     FontSize="100" 
     Content="{Binding Path=ButtonText, 
          UpdateSourceTrigger=PropertyChanged, 
          Mode=TwoWay}" 
     Margin="0,185,0.133,0.4"/> 

這是我的.vb文件：

Imports System.ComponentModel 

Class MainWindow 

#Region "INotifyPropertyChanged Interface" 
Implements INotifyPropertyChanged 

Public Event PropertyChanged As PropertyChangedEventHandler Implements INotifyPropertyChanged.PropertyChanged 

Protected Sub NotifyPropertyChanged(ByVal propertyName As String) 
    RaiseEvent PropertyChanged(Me, New PropertyChangedEventArgs(propertyName)) 
End Sub 
#End Region 

#Region "Properties" 
Public Property ButtonText As String 
    Get 
     Return propText 
    End Get 
    Set(value As String) 
     propText = value 
     NotifyPropertyChanged("ButtonText") 
    End Set 
End Property 
#End Region 

Private propText As String 

Private Sub Button_Click(sender As Object, e As RoutedEventArgs) 
    'If propText Is "Test" Then 
    propText = "Suc6" 
    'ElseIf propText Is "Suc6" Then 
    'propText = "Test" 
    'End If 
End Sub 
End Class 

如果我按下按鈕，他的內容應顯示「Suc6 「，但這是失敗的。我做錯了什麼？我一直在閱讀http://www.codeproject.com/Articles/26210/Moving-Toward-WPF-Data-Binding-One-Step-at-a-Time和http://msdn.microsoft.com/en-us/library/system.componentmodel.inotifypropertychanged.aspx?cs-save-lang=1&cs-lang=vb#code-snippet-1，但無法弄清楚我做錯了什麼。

Answer 1

這是您的VB版本，我測試了它的工作原理是肯定的。

Imports System.ComponentModel 

Public Class MainWindow 
    Implements INotifyPropertyChanged 
    Public Event PropertyChanged As PropertyChangedEventHandler Implements INotifyPropertyChanged.PropertyChanged 

    Protected Sub NotifyPropertyChanged(ByVal propertyName As String) 
     RaiseEvent PropertyChanged(Me, New PropertyChangedEventArgs(propertyName)) 
    End Sub 

    Public Sub New() 
     ' This call is required by the designer. 
     InitializeComponent() 
     Me.DataContext = Me 
    End Sub 

    Private propText As String 
    Public Property ButtonText As String 
     Get 
      Return propText 
     End Get 
     Set(value As String) 
      propText = value 
      NotifyPropertyChanged("ButtonText") 
     End Set 
    End Property 


    Private Sub Button_Click(sender As Object, e As RoutedEventArgs) 
     ButtonText = "Suc6" 
    End Sub 
End Class 

Answer 2

與ButtonText在Button_Click替換propText

Private Sub Button_Click(sender As Object, e As RoutedEventArgs) 
    ButtonText= "Suc6" 
End Sub 

而且我會做下面的構造函數來設置的DataContext

public MainWindow() 
    { 
     InitializeComponent(); 
     this.DataContext = this;    
    }