刪除未格式化爲日期的行

Question

在我的專欄A中，我有格式化日期和常規格式組成的單元格。我想刪除不是日期的行，並且我已經創建了這些代碼，但是我必須多次運行它才能刪除所有不是日期的行。

代碼：

Sub del_row_not_date() 

Dim rng_A_last As Long 
Dim i As Integer 

rng_A_last = Sheet1.Cells(Sheet1.Rows.Count, "A").End(xlUp).Row 
Debug.Print rng_A_last 

For i = 1 To rng_A_last Step 1 
    If IsDate(Sheet1.Cells(i, 1)) = False Then 
     Sheet1.Cells(i, 1).EntireRow.Delete 
    End If 
Next 
End Sub 

提前感謝！

Answer 1

由於行將

基於此LINK我發現這個：

關於根據條件刪除行的提示如果你從頂部開始往下看，每次刪除一行時，你的計數器將有效地移動到你刪除的行下面兩行的單元格，因爲立即行在刪除的行下移動（即它根本沒有經過測試）。

這工作:)

Sub del_row_not_date() 

Dim rng_A_last As Long 
Dim i As Integer 

rng_A_last = Sheet1.Cells(Sheet1.Rows.Count, "A").End(xlUp).Row 
Debug.Print rng_A_last 

For i = rng_A_last To 1 Step -1 
    'Debug.Print Cells(i, 1).Value 
    If IsDate(Sheet1.Cells(i, 1)) = False Then 
     Sheet1.Cells(i, 1).EntireRow.Delete 
    End If 
Next 
End Sub 

Answer 2

你可以嘗試

Sub del_row_not_date() 
    With Sheet1 
     .Range("A1", .Cells(.Rows.Count, "A").End(xlUp)).SpecialCells(xlCellTypeConstants, xlTextValues).EntireRow.Delete 
    End With 
End Sub 

什麼上面刪除所有列「A」不數字的單元格整行

，如果你有細胞與不是日期，然後用數字：

Option Explicit 

Sub del_row_not_date() 
    Dim i As Integer 

    With Sheet1 
     For i = .Cells(.Rows.Count, "A").End(xlUp).Row To 1 Step -1 '<--| loop backwards not to loose next row index after deleting the current one 
      If Not IsDate(.Cells(i, 1)) Then .Cells(i, 1).EntireRow.Delete 
     Next i 
    End With 
End Sub