以編程方式配置SQL Server TCP設置

我們每當爲客戶安裝SQL Server 2008 R2時都會執行手動過程。我們爲實例啓用TCP/IP和Named Pipes協議，將TCP Dynamic Ports設置爲0，並將TCP Port設置爲非標準端口號（爲安全起見故意禁用瀏覽器）。連接總是使用明確的端口號（I.E. 192.168.1.100, 12345）以編程方式配置SQL Server TCP設置

如何從Delphi中以編程方式配置這些服務器TCP設置？

來源

2014-01-29 Jerry Dodge

實際上，答案是：根據您的SQL服務器版本更改註冊表中的端口號，然後重新啓動服務... – whosrdaddy

由於此問題收到了很好的備選答案，因此刪除了近距離投票。 – whosrdaddy

您可以使用ServerNetworkProtocol WMI類，它是WMI Provider for Configuration Management Classes的一部分。

要訪問此類，您必須連接到適當的名稱空間，具體取決於您的SQL Server版本。

SQL Server 2005 - ComputerManagement 
SQL Server 2008 - ComputerManagement10 
SQL Server 2012 - ComputerManagement11

試試這個樣本的SQL Server 2008

{$APPTYPE CONSOLE} 

uses 
    SysUtils, 
    ActiveX, 
    ComObj, 
    Variants; 


procedure EnableSQLServerNetworkProtocol(Const Protocol : string; EnableProtocol: Boolean); 
const 
    WbemUser   =''; 
    WbemPassword  =''; 
    WbemComputer  ='localhost'; 
    wbemFlagForwardOnly = $00000020; 
var 
    FSWbemLocator : OLEVariant; 
    FWMIService : OLEVariant; 
    FWbemObjectSet: OLEVariant; 
    FWbemObject : OLEVariant; 
    oEnum   : IEnumvariant; 
    iValue  : LongWord; 
begin; 
    FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator'); 
    FWMIService := FSWbemLocator.ConnectServer(WbemComputer, 'root\Microsoft\SqlServer\ComputerManagement10', WbemUser, WbemPassword); 
    FWbemObjectSet:= FWMIService.ExecQuery(Format('SELECT * FROM ServerNetworkProtocol Where ProtocolName="%s"', [Protocol]),'WQL',wbemFlagForwardOnly); 
    oEnum   := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant; 
    if oEnum.Next(1, FWbemObject, iValue) = 0 then 
    //if FWbemObject.Enabled<>EnableProtocol then 
     Writeln('Result '+VarToStr(FWbemObject.SetEnable(EnableProtocol))); // 0 means OK 
end; 


begin 
try 
    CoInitialize(nil); 
    try 
     EnableSQLServerNetworkProtocol('Tcp', True);// TCP/IP 
     EnableSQLServerNetworkProtocol('Np', True); // Named Pipes 
    finally 
     CoUninitialize; 
    end; 
except 
    on E:EOleException do 
     Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode])); 
    on E:Exception do 
     Writeln(E.Classname, ':', E.Message); 
end; 
Writeln('Press Enter to exit'); 
Readln; 
end.

注：此代碼必須在安裝SQL Server在同一臺機器，如果你想要做這個任務遠程您必須提供正確的執行，登錄參數（用戶，傳遞，服務器）到WMI連接。

要設置IP地址和端口，您可以使用ServerNetworkProtocolIPAddress和ServerNetworkProtocolProperty類。

來源

2014-01-29 06:39:12 RRUZ

^+ 1。 WMI能爲我做啤酒嗎？ :) – whosrdaddy

+1並被接受，即使我仍然直接使用註冊表（WMI可以停止，註冊表不能） –

以編程方式配置SQL Server TCP設置

回答

相關問題