VB.NET Web應用程序 - 不需要用戶會話共享

Question

我是很新的vb.net因爲我更是一個PHP開發人員，但無論如何的。我已經構建了一個Web應用程序，但我的用戶似乎正在共享我不想要的同一個會話，並且無法理解原因。我從一個模塊的全局屬性中訪問存儲所有會話信息的對象，這可能是原因嗎？

的代碼如下：你爲什麼要使用一個靜態類（模塊）作爲信息庫用於Session對象

Module SiteWide 
    Private mUserSession As New MyLib.User.UserSession 
    Public Property gUserSession() As MyLib.User.UserSession 
     Get 
      If Not HttpContext.Current Is Nothing AndAlso Not HttpContext.Current.Session Is Nothing Then 
       If Not HttpContext.Current.Session("user") Is Nothing Then 
        mUserSession = HttpContext.Current.Session("user") 
       End If 
      End If 

      Return mUserSession 
     End Get 
     Set(ByVal value As MyLib.User.UserSession) 
      mUserSession = value 

      If Not HttpContext.Current Is Nothing AndAlso Not HttpContext.Current.Session Is Nothing Then 
       HttpContext.Current.Session("user") = value 
      End If 
     End Set 
    End Property 
End Module 

Answer 1

？靜態意味着應用廣泛。 mUserSession也是隱式靜態的，因此所有用戶共享同一個Session。其實線

mUserSession = value 

中的getter/setter

和

mUserSession = HttpContext.Current.Session("user") 

被覆蓋它的所有用戶。

你可以換Session對象在自己的類只是簡化：

例如：

Public Class MySession 
    ' private constructor 
    Private Sub New() 
    End Sub 

    ' Gets the current session. 
    Public Shared ReadOnly Property Current() As MySession 
     Get 
      Dim session As MySession = DirectCast(HttpContext.Current.Session("__MySession__"), MySession) 
      If session Is Nothing Then 
       session = New MySession() 
       HttpContext.Current.Session("__MySession__") = session 
      End If 
      Return session 
     End Get 
    End Property 

    ' **** add your session properties here, e.g like this: 
    Public Property MyID() As Guid 
     Get 
      Return m_ID 
     End Get 
     Set(value As Guid) 
      m_ID = value 
     End Set 
    End Property 
    Private m_ID As Guid 

    Public Property MyDate() As DateTime 
     Get 
      Return m_MyDate 
     End Get 
     Set(value As DateTime) 
      m_MyDate = Value 
     End Set 
    End Property 
    Private m_MyDate As DateTime 

End Class 

注意：該Current - 屬性也共享/靜態的，但不同的是我返回HttpContext.Current.Session而您正在返回單個/共享實例。