搜索兩個字符串，然後將結果加在一起

Question

我正在嘗試製作一個批處理文件，用於在文件中搜索兩個不同的字符串。然後從第一個搜索中取第一行，從第二個搜索中取第一行，並將它們組合成一行。

我意識到這是對我的技能批量的方式，所以一點幫助，將不勝感激。

在此先感謝！

---

@echo off 
for /f %%G in (file.txt) do (
findstr "word1" *.* > result.txt 
findstr "word2" *.* >> result.txt) 

---

實施例：

file.txt的：

hello i'm a line with word1 
hello i'm a line with word2 
hello i'm another line with word1 
hello i'm another line with word2 
hello i'm yet another line with word1 
hello i'm yet another line with word2 

的Result.txt：

hello i'm a line with word1hello i'm a line with word2 
hello i'm another line with word1hello i'm another line with word2 
hello i'm yet another line with word1hello i'm yet another line with word2 

Answer 1

集合L的數量ine對顯示在變量中PairsToShow：

@ECHO OFF &SETLOCAL 
SET "FileName=file.txt" 
SET "Word1=word1" 
SET "Word2=word2" 
SET /a PairsToShow=3 

SET /a Lines1=0, Lines2=0 
FOR /f "delims=" %%a IN ('findstr "%Word1%" "%FileName%"') DO (
    SET "str=%%a" 
    SET /a Lines1+=1 
    SETLOCAL enabledelayedexpansion 
    SET "$1!Lines1!=!str!" 
    FOR /f "tokens=1*delims==" %%b IN ('set "$1"') DO (IF "!"=="" endlocal)&SET "%%b=%%c" 
) 
FOR /f "delims=" %%a IN ('findstr "%Word2%" "%FileName%"') DO (
    SET "str=%%a" 
    SET /a Lines2+=1 
    SETLOCAL enabledelayedexpansion 
    SET "$2!Lines2!=!str!" 
    FOR /f "tokens=1*delims==" %%b IN ('set "$2"') DO (IF "!"=="" endlocal)&SET "%%b=%%c" 
) 
SET /a Lines=Lines1+Lines2 
ECHO(%Lines% lines read from %FileName%. 
IF %Lines1% leq %Lines2% (SET /a MaxPairs=Lines1) ELSE SET /a MaxPairs=Lines2 
IF %PairsToShow% gtr %MaxPairs% (
    ECHO only text for %MaxPairs% pairs NOT %PairsToShow% :/ 
    GOTO :END 
) 
(FOR /l %%a IN (1,1,%PairsToShow%) DO (
    SETLOCAL ENABLEDELAYEDEXPANSION 
    CALL SET "Line1=%%$1%%a%%" 
    CALL SET "Line2=%%$2%%a%%" 
    <NUL SET /p "=!Line1!" 
    ECHO !Line2! 
    ENDLOCAL 
))> result.txt 
ENDLOCAL 
TYPE result.txt 
:END 
PAUSE