Excel中時間戳數據的自動插值

Question

我有6分鐘的時間間隔收集現有數據。時間戳在列A中，相應的值在列B中。

我想插入此數據以獲得按分鐘細分的分數，使用基本插值方法計算。所需輸出的樣本顯示在D和E列中。

有沒有一種方法可以自動執行此計算？

Answer 1

我寫了我自己的插值函數。它不是爲日期設計的，因此您需要修改參數。這對你來說可能是一個很好的起點。第一個參數是要插入的數據點。第二個參數是定義曲線的輸入數據的範圍。請注意，當數據點超出範圍時，返回值將是最近的數據點，而不是外推值。

Function interpolate(inp As Double, rng As Range) 
' written by: Todd Wegner 
' 
' inp --> the data point to interpolate 
' rng --> the range of original data 
' 
' early binding 
Dim i As Long, dim1 As Long 
Dim x1 As Double, x2 As Double, y1 As Double, y2 As Double 
Dim arr As Variant 
' 
' set array to the Range(rng) 
    arr = rng 
' 
' if the input is below the data bounds 
' use the first data point, DO NOT extrapolate 
    If inp < arr(1, 1) Then 
    interpolate = arr(1, 2) 
    Exit Function 
    End If 
' 
' get array upper bound 
    dim1 = UBound(arr) 
' 
' if the input is above the data bounds 
' use the last data point, DO NOT extrapolate 
    If inp > arr(dim1, 1) Then 
    interpolate = arr(dim1, 2) 
    Exit Function 
    End If 
' 
' inputs that lie within the data range get interpolated 
    i = 1 
    Do Until inp < arr(i, 1) 
    i = i + 1 
    Loop 
    x1 = arr(i - 1, 1) 
    x2 = arr(i, 1) 
    y1 = arr(i - 1, 2) 
    y2 = arr(i, 2) 
' 
' return 
    interpolate = (y2 - y1)/(x2 - x1) * (inp - x1) + y1 
' 
End Function 

Answer 2

你可以嘗試從E1充絨：

=PERCENTILE(B$1:B$7,PERCENTRANK(A$1:A$7,D1,30)) 

（假定值不減少）