的Excel 2013複雜COUNTIF式

我有一個源片設置是這樣的：的Excel 2013複雜COUNTIF式

Days Open  Month 
10    1 
4    1 
6    1 
2    1 
4    2 
2    2 
-1    2 
4    3 
6    3 
7    4 
3    4

等

我試圖建立一個公式來計算基於下列條件的行：

單元格在Days Open列< = 5和<> -1其中月份爲2,3或4（工作表最終將月份數最多爲12，我需要按季度對結果進行分組）。總數必須除以「月份」列中出現2,3或4的所有行的總數。

我似乎無法得到COUNTIFS用兩個標準來工作的第一部分...這是我到目前爲止，我試圖做的工作：

=COUNTIFS('Cumulative Complaints'!K:K,"<=5",'Cumulative Complaints'!K:K,"<>-1")/(COUNTIF('Cumulative Complaints'!L:L,"2")+COUNTIF('Cumulative Complaints'!L:L,"3")+COUNTIF('Cumulative Complaints'!L:L,"4"))

我一直在環顧這裏和其他Excel論壇，並認爲也許SUMPRODUCT是要走的路？根據Days Days欄中所需的條件（< = 5和<> -1），我還是無法完成此工作。

來源

2016-02-04 mattinwpg

結束語在SUM function一個COUNTIF或COUNTIFS功能可以使用常量的數組作爲OR citeria。

=SUM(COUNTIFS('Cumulative Complaints'!K:K, "<>"&-1,'Cumulative Complaints'!K:K, "<="&5,'Cumulative Complaints'!L:L, {2,3,4}))/SUM(COUNTIF('Cumulative Complaints'!L:L, {2,3,4}))

這不是數組公式，也不需要CSE。

來源

2016-02-04 20:19:51 Jeeped

輝煌！謝謝。 – mattinwpg

嘗試此SUMPRODUCT（）公式：

=SUMPRODUCT(('Cumulative Complaints'!K:K<=5)*('Cumulative Complaints'!K:K<>-1)*('Cumulative Complaints'!L:L>=2)*('Cumulative Complaints'!L:L<=4))/SUMPRODUCT(('Cumulative Complaints'!L:L>=2)*('Cumulative Complaints'!L:L<=4))

當使用條件AND被替換爲*的SUMPRODUCT。它要求所有四個條件都爲真來返回1; 1 * 1 * 1 * 1 = 1如果其中任何一個爲假，它們返回0，所以1 * 1 * 0 * 1 = 0.所以當它在行中迭代時，它返回1或0以被添加到總和中。

來源

2016-02-04 20:05:47

對不起，我一直在強調這是一個多麼糟糕的想法，它是參考SUMPRODUCT中的整個列。雖然這樣的做法在使用COUNTIF（S）/ SUMIF（S）時不會造成損害，但對於SUMPRODUCT（或任何其他陣列處理函數）並非全部。除非OP確實有數據擴展到100萬以上，否則您會要求Excel檢查比實際需要更多的數十萬個單元。 –

我的答案是採取不同的方法。

Excel有一個非常強大的功能，稱爲透視表，我認爲它可能很適合您的問題以及其他類似的問題。

首先，我會加入一列到表，就像這樣：

Days Open Month Quarter RecentlyOpened 
    10   1  1  FALSE 
    4   1  1  TRUE 
    6   1  1  FALSE 
    2   1  1  TRUE 
    4   2  1  TRUE 
    2   2  1  TRUE 
    -1   2  1  FALSE 
    4   3  1  TRUE 
    6   3  1  FALSE 
    7   4  2  FALSE 
    3   4  2  TRUE

的季度公式爲：=CEILING(B2/3,1)
爲RecentlyOpened其計算公式爲：=AND(A2<>-1,A2<=5)

其次，選擇表格，並執行插入>數據透視表。

第三，從田間地頭到箱子，像這樣拖：

拖動季度對行框
將RecentlyOpened到過濾器盒
拖動月到值框

第四，單擊總和月份，然後選擇值字段設置以將總和更改爲計數。

第五，將RecentOpened過濾器設置爲TRUE。

結果是這樣的：

透視表通常會提供一個解決方案，更靈活，更易於閱讀和理解相對複雜的公式。

來源

2016-02-04 20:21:53 devuxer

我喜歡你的數據透視表解決方案，它更優雅......但是由於這個工作簿格式化的方式，我需要在其他地方可以引用的單元格中的％結果。謝謝！ – mattinwpg

數據透視表的單元格可以像任何單元格一樣訪問。因此，您可以從另一個工作表中的數據透視表中引用B4，或者您可以編寫一個類似'= Sheet2！B4/Sheet2！B6'的公式來獲取您正在查找的百分比。 – devuxer

的Excel 2013複雜COUNTIF式

回答

相關問題