將xmlns屬性添加到使用XSL的XML文檔的問題

Question

在我的XSL中添加了xmlns到我的XML中。

<xsl:template match="root"> 
    <xsl:element name="root" namespace="myXslLoc"> 
     <xsl:attribute name="Name">Default</xsl:attribute> 
     <xsl:apply-templates/> 
    </xsl:element> 
<xsl:template> 

上面確實爲根元素（頂層元素）添加了xmlns屬性。但是它也爲後續元素添加了xmlns。這是事實：

<root Name="Default" xmlns="myXslLoc"> 
    <steps xmlns=""> <-- where did this attribute come from? 
    . 
    . 
    . 
    </steps> 
</root> 

我不知道step元素中的xmlns來自哪裏。我沒有指定將xmlns添加到steps元素的代碼。下面是我的xsd snipet：

<xs:complexType name="root"> 
    <xs:sequence> 
     <xs:element name="steps" type="steps" maxOccurs="1" MinOccurs="1"/> 
    </xs:sequence> 
    <xs:attribute name="Name" type="xs:string" use="required"/> 
</xs:complexType> 

<xs:complexType name="steps"> 
    <xs:sequence> 
     <xs:element name="step" type="step" maxOccurs="unbounded"/> 
    </xs:sequence> 
</xs:complexType> 

在我的xsl或xsd中是否有問題？我似乎無法弄清楚問題來自哪裏。

謝謝。

編輯： 以下Dimitre的轉換代碼，我設法將名稱空間屬性插入根元素。然而，更多的名稱空間屬性實例出現在轉換後的xml文檔中。

下面是發生了什麼：

<root Name="Default" xmlns="myXslLoc"> 
    <steps> <-- where did this attribute come from? 
     <step name="A"> 
     . 
     </step> 
     . 
     . 
     <!-- the below is the final steps element --> 
     <step name="Z" xmlns=""> <-- this xmlns was unexpectedly added. 
      <steps xmlns="myXslLoc"> <-- this one as well. 
      . 
      . 
      . 
      </steps> 
     </step> 
     <step Name="Step manually added by identity transformation (addLastNode stuff)"> 
     . 
     . 
     . 
     </step> 
    </steps> 
</root> 

的XSL看起來是這樣的：

<xsl:template match="root"> 
    <xsl:element name="root namespace="myXslLoc"> 
     <xsl:attribute name="Name">Default</xsl:attribute> 
     <xsl:apply-templates/> 
    </xsl:element> 
<xsl:template> 

<xsl:template match="*"> 
    <xsl:element name="{name()}" namespace="{$addMyXslLoc}"> 
     <xsl:copy-of select="namespace::*"/> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:element> 
<xsl:template> 

<xsl:param name="addMyXslLoc" select="'myXslLoc'"/> 

<xsl:template match="/*/steps/step[position()=last()]"> 
    <xsl:call-template name="identity"/> 
    <xsl:copy-of select="$addLastNodes"/> 
</xsl:template> 

<xsl:param name="addLastNodes"> 
    <step Name="Total Cost"> 
     <items> 
      <item name="A"> 
      </item> 
      <item name="b"> 
      </item> 
     </items> 
    </step> 
</xsl:param> 

<xsl:template match="node()|@*" name="identity"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

我喜歡怎樣的命名空間，現在的根元素上出現（連同名稱屬性）。但是我現在面臨的問題是無法擺脫插入到xml文檔的最後一個元素中的名稱空間，不包括通過轉換添加的名稱空間。編輯： 更新了addLastNodes xsl。

Answer 1

@ Vincent-Marchetti已經解釋了導致問題的原因。這是一個完整的解決方案。

這種轉變：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:ext="http://exslt.org/common" 
exclude-result-prefixes="ext" 
> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:param name="pNamespace" select="'myXslLoc'"/> 

    <xsl:param name="addLastNodes"> 
    <step Name="Total Cost"> 
     <items> 
      <item name="A"> 
      </item> 
      <item name="b"> 
      </item> 
     </items> 
    </step> 
</xsl:param> 


    <xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

    <xsl:template match="/*/steps/step[position()=last()]"> 
    <xsl:call-template name="repNamespace"/> 
    <xsl:apply-templates select="ext:node-set($addLastNodes)/*"/> 
</xsl:template> 

<xsl:template match="*" name="repNamespace"> 
    <xsl:element name="{name()}" namespace="{$pNamespace}"> 
    <xsl:copy-of select="namespace::*"/> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:element> 
</xsl:template> 
</xsl:stylesheet> 

當這個XML文檔施加：

<root> 
<steps> 
    <step>1</step> 
    <step>2</step> 
    <step>3</step> 
</steps> 
</root> 

產生想要的，正確的結果：

<root xmlns="myXslLoc"> 
    <steps> 
     <step>1</step> 
     <step>2</step> 
     <step>3</step> 
     <step Name="Total Cost"> 
     <items> 
      <item name="A"/> 
      <item name="b"/> 
     </items> 
     </step> 
    </steps> 
</root> 

Answer 2

XSL模板沒有問題;它只是沒有做你想做的事情。

它正在做的是在myXslLoc命名空間中創建一個元素'root'，然後（在apply-template步驟中）將上下文節點的子節點（root，在NoNameSpace中）複製到它們的子節點中命名空間，它是NoNameSpace;所以你的結果是父節點{myXslLoc}根節點，子節點{}步驟

如果你想要的是步驟元素也在myXslLoc根目錄下，你需要使用顯式創建{myXslLoc}步驟節點XSL：元件;就像您爲「根」模板所做的一樣。