傳遞的參數與條件不匹配

Question

我試圖將參數從一個過程傳遞到另一個過程。一切都看起來不錯，參數已通過，但它符合Select case方案中給出的條件。

我在做什麼錯？

程序通過參數：

Private Sub but_next_Click() 

Call zmien_fakture("but_next") 

End Sub 

步驟接收的參數：

Private Sub zmien_fakture(ByVal txt_name As String) 

Select Case txt_name 

    Case txt_name = "but_next" 
     If Lastrow > nr_faktury_dol Then 
      nr_faktury_dol = nr_faktury_dol + 1 

     Else 
      MsgBox ("To jest ostatnia faktura") 

     End If 

    Case txt_name = "but_prev" 
     If nr_faktury_dol <> 1 Then: nr_faktury_dol = nr_faktury_dol - 1 

    Case Else 

End Select 

End Sub 

Answer 1

Case "but_next"與替換Case txt_name = "but_next"。正確的代碼是：

Private Sub zmien_fakture(ByVal txt_name As String) 
    Select Case txt_name 
     Case "but_next" 
      If Lastrow > nr_faktury_dol Then 
       nr_faktury_dol = nr_faktury_dol + 1 
      Else 
       MsgBox ("To jest ostatnia faktura") 
      End If 
     Case "but_prev" 
      If nr_faktury_dol <> 1 Then: nr_faktury_dol = nr_faktury_dol - 1 
     Case Else 
    End Select 
End Sub 

爲什麼你的語法不工作：

當你使用Case txt_name = "but_next"，聲明txt_name = "but_next"評估爲TRUE或FALSE，你會得到：

Select Case txt_name ' txt_name="but_next", but txt_name<>TRUE and txt_name<>FALSE 
    Case True 
     'do something 
    Case False 
     'do something 
    Case Else 
End Select 

但在Select Case txt_name變量txt_name不是True或False而你實際跳躍到Case Else部分。

另一種方法是改變Select Case txt_name到Select Case TRUE這樣的：

Private Sub zmien_fakture(ByVal txt_name As String) 
    Select Case True 
     Case txt_name = "but_next" 
      If Lastrow > nr_faktury_dol Then 
       nr_faktury_dol = nr_faktury_dol + 1 
      Else 
       MsgBox ("To jest ostatnia faktura") 
      End If 
     Case txt_name = "but_prev" 
      If nr_faktury_dol <> 1 Then: nr_faktury_dol = nr_faktury_dol - 1 
     Case Else 
    End Select 
End Sub