批處理腳本多選

Question

如果提示您如何允許用戶在批處理腳本中鍵入多個數字？

如果它向用戶提示5個選項。並且用戶想要選擇1,2,3但不想要4,5，如何在批處理腳本中執行此操作？

我refered到Allowing multiple choice selections for users using batch file和Multiple choices menu on batch file?

有計算器中的相關問題，但沒有答案，因爲答案是不正確的地步。

任何幫助將不勝感激。

Answer 1

這個答案也提到了這個問題：How to integrate batch script multiple selections into JAVA GUI?

你可能想在頂部加入一行刪除family.txt如果你想要一個新的文件，每次。

@echo off 
echo. 
echo Selection time! 
echo. 
echo 1. My father is Joe 
echo 2. My mother is Audrey 
echo 3. My brother is Jerry 
echo 4. My elder sister is June 
echo 5. My youngest sister is Awy 
echo 6. Include All 
echo. 

:getOptions 
set "choices=" 
set /p "choices=Type your choices without spacing (e.g. 1,2,3): " 

if not defined choices ( 
    echo Please enter a valid option 
    goto getOptions 
    ) 

for %%a in (%choices%) do if %%a EQU 6 set choices=1,2,3,4,5 
for %%i in (%choices%) do call :option-%%i 

echo. 
echo Done 
pause 
exit 

:option-1 
>> Family.txt echo My father is Joe 
exit /B 

:option-2 
>> Family.txt echo My mother is Audrey 
exit /B 

:option-3 
>> Family.txt echo My brother is Jerry 
exit /B 

:option-4 
>> Family.txt echo My elder sister is June 
exit /B 

:option-5 
>> Family.txt echo My youngest sister is Awy 
exit /B 

Answer 2

像這樣：

@echo off 

set /p "$choix=Enter you(s) Choice (1,2,...): " 
for %%a in (%$choix%) do call:choix%%a 
exit/b 


:choix1 
echo Choice 1 
exit/b 

:choix2 
echo Choice 2 
exit/b 

:choix3 
echo Choice 3 
exit/b