批處理腳本工作在32位，但不工作的64位

Question

我有以下未Win7上工作.bat文件64個bit.I希望它的64位also.Please healp

@echo off 
setlocal disableDelayedExpansion 


set x=^ 


rem for /f %%? in ('2^>nul ^(^< output.md find /c /v "" ^)') do set "$end=%%?" 

rem echo.linefeeds[%$end%] 


< output.md (

    for /l %%i in (1, 1, 100) do set "b=" &set /p "b=" &(

     setlocal enabledelayedexpansion 
     (set /p y=!b!!x! <nul) 
     endlocal 
    ) 
) > out.md 

Answer 1

Win7上運行在Windows Vista中，set /p命令在輸出提示開始時刪除空格和製表符。您不能使用在Windows這個方法7

對於純一批解決方案，您可以使用

@echo off 
    setlocal enableextensions disabledelayedexpansion 

    rem Configure files 
    set "inputFile=input.txt" 
    set "outputFile=output.txt" 

    rem A temp file is needed 
    set "tempFile=%temp%\%~nx0.%random%%random%%random%.tmp" 
    rem Retrieve a line feed into a variabla 
    set LF=^ 



    rem Retrieve a SUB (0x1A) character into a variable 
    copy nul "%tempFile%" /a >nul 
    for /f "usebackq" %%a in ("%tempFile%") do set "SUB=%%a" 

    rem For each line inside input file 
    (for /f "usebackq delims=" %%a in ("%inputFile%") do (
     rem Retrieve the line contents 
     set "line=%%a" 

     rem Output the line, a line feed a SUB and the CRLF (from echo) to a file 
     setlocal enabledelayedexpansion 
     >"%tempFile%" (echo(!line!!LF!!sub!) 
     endlocal 

     rem From the generated file, copy everything up to the SUB character 
     rem The SUB and everything after it will be discarded 
     >nul copy "%tempFile%" /a "%tempFile%2" /b 

     rem Output the generated line 
     type "%tempFile%2" 

    )) > "%outputFile%" 

    rem Remove temporary files used 
    del /q "%tempFile%*" 

但更高效的解決方案將使用在操作系統中可用的本地腳本引擎。

這是一種混合CMD/JScript的批處理文件（帶有.cmd擴展名保存）被用作

cr2lf.cmd <inputfile> outputFile 

該代碼將剛剛讀取標準輸入和對於每個輸入線路輸出的同一行，接着用線飼料字符

@if (@This==@IsBatch) @then 
@echo off 
rem **** batch zone ********************************************************* 

    setlocal enableextensions disabledelayedexpansion 
    call :runInnerScript 
    exit /b 

:runInnerScript 
    cscript //E:JScript "%~f0" 
    goto :eof 

@end 
// **** Javascript zone ***************************************************** 

    while (!WScript.StdIn.AtEndOfStream){ 
     WScript.StdOut.Write(WScript.StdIn.ReadLine() + '\n'); 
    }; 
    // All done. Exit 
    WScript.Quit(0);