當輸入空行時，Perl while循環不會退出

Question

我試圖打印數字列表的總和，最大值和最小值，但我努力讓它工作。

當我按下Enter鍵循環應該退出，但是程序繼續運行

use strict; 
use warnings; 

my @items; 
my ($sum, $max, $min); 

while (chomp(my $num = <STDIN>)) { 
    last if ($num eq '\n'); 

    $max ||= $num; 
    $min ||= $num; 
    $sum += $num; 

    $max = $num if ($num > $max); 
    $min = $num if ($num < $min); 

    push(@items, $num); 
} 

printf("Entered numbers are: %s \n", join(', ', @items)); 
print("Sum of all numbers is : ", $sum); 
print "\n"; 
print("Minimum number is : ", $min); 
print "\n"; 
print("Maximum number is : ", $max) 

Answer 1

• 因爲while循環需要終止您不能使用chomp一個while條件內像這樣

  while (chomp(my $num = <STDIN>)) { ... } 
  

  時在文件末尾的<>回報undef。所以，你必須把chomp作爲循環

• 的第一個語句的最簡單方式退出循環像這樣的檢查輸入是否包含使用正則表達式/\S/

• 的任何非空格字符檢查

  last if ($num eq '\n') 
  

  將不起作用，因爲您已使用chomp從輸入中刪除換行符。此外，如果您使用單引號'\n'是兩個字符的字符串\，然後是n。你需要雙引號像"\n"創建一個新行

• 當一個標量首次宣佈它的值爲undef，這樣你就可以通過測試這一點，並更新$min和$max除非以前的值已經是避免任何笨拙的初始化並且比新值更高（或更低）

我會像這樣重寫你的程序。

use strict; 
use warnings; 

my @items; 
my ($sum, $max, $min); 

while (my $num = <STDIN>) { 
    chomp $num; 
    last unless $num =~ /\S/; 

    $max = $num unless defined $max and $max >= $num; 
    $min = $num unless defined $min and $min <= $num; 
    $sum += $num; 
    push @items, $num; 
} 

print 'Entered numbers are: ', join(', ', @items), "\n"; 
print "Sum of all numbers is: $sum\n"; 
print "Minimum number is: $min\n"; 
print "Maximum number is: $max\n"; 

Answer 2

如果你想檢測輸入，你不能chomp輸入之前。另外，'\n'不是輸入，您必須使用雙引號"\n"來啓用特殊字符。

while (<>)循環通常以結束Ctrl + D。

此外，您可以找到一個模塊爲您完成工作。

#!/usr/bin/perl 
use warnings; 
use strict; 

use List::Util qw{ max min sum }; 

my @items = <>; 
chomp @items; 
my $max = max(@items); 
my $min = min(@items); 
my $sum = sum(@items); 

print "Entered numbers are: @items\n"; 
print "Sum of all numbers is: $sum\n"; 
print "Minimum number is: $min\n"; 
print "Maximum number is: $max";